Selasa, 24 Juni 2008
Tinggal 1 mata kuliah lagi ne... dan libur panjang pun akan segera dimulai
Rencana yang dari dulu di persiapkan, yaitu berlibur ke malang akhirnya batal,,, he he he
Ini karena salah seorang teman kami yang di Asia Academy berhalangan, akhirnya semua jadi tak bersemangat.. dan kompakan membatalkannya..
Tapi gak papa, toh masih ada bali, he he, liburan di bali kan asik juga, malah mungkin lebih asik he he. Gimana sich, orang saya ada di bali he he...
welcome holyday...
Jumat, 20 Juni 2008
Ini tulisan khusus untuk membantu uas anak2 asia
mari kita mulai
BAB IX
POINTER
9.1. PENDAHULUAN
Pada program-program sebelumnya(pengurangan,perkalian dan pembagian) dapat anda lihat bahwa hasil dari operasi aritmatika disimpan dalam 2 variabel dimana 1 variabel untuk menampung hasil dari word tingginya dan 1 word untuk menampung word rendahnya. Bukankah hal ini akan tampak menjadi aneh, karena bila kita ingin melihat nilai tersebut maka nilai tersebut harus disatukan barulah dapat dibaca. Apakah ada cara lain supaya hasilnya dapat disimpan pada satu variabel saja ? YA!!, tetapi untuk itu anda harus menggunakan pointer untuk mengaksesnya. Bila anda tidak menggunakan pointer maka tipe data penampung harus sesuai dengan registernya. Tanpa pointer untuk memindahkan data dari suatu variabel ke register 8 bit, maka variabel tersebut haruslah 8 bit juga yang dapat didefinisikan dengan DB, demikian juga untuk register 16 bit dengan variabel yang didefinisikan dengan DW. Contoh :
A DB 17 ; DB=8 bit jadi A=8 bit
B DW 35 ; DW=16 bit jadi B=16 bit
:
MOV AL,A ; 8 bit dengan 8 bit
MOV AX,B ; 16 bit dengan 16 bit.
Seperti pada contoh diatas anda tidak bisa menggunakan perintah MOV AX,A karena kedua operand tidak mempunyai daya tampung yang sama(16 dan 8 bit). Bila anda melakukan pemindahan data dari operand yang berbeda tipe data penampungnya maka akan ditampikan "**Error** BAGI.ASM(20) Operand types do not match". Dengan menggunakan pointer hal ini bukanlah masalah. Sebelum itu marilah kita lihat dahulu berbagai tipe data yang terdapat pada assembler.
9.2. TIPE DATA
Didalam assembler kita bisa menyimpan data dengan berbagai tipe data yang berbeda-beda. Kita dapat memberikan nama pada data tersebut, untuk memudahkan dalam pengaksesan data tersebut. Adapun tipe data yang terdapat pada assembler dapat anda lihat pada gambar 9.1.
------------------------------------------
NAMA UKURAN
------------------------------------------
40
DB
DW
DD
DF
DQ
DT
-------------------------------------------
Gambar 9.1. Berbagai Tipe Data
Sebagai contohnya lihatlah bagaimana tipe data pada gambar 9.1. digunakan :
.MODEL SMALL
.CODE
ORG 100h
TData :
JMP Proses
A DB 4 ; 1 byte, nilai awal='4'
B DB 4,4,4,2,? ; 1*5 byte, nilai awal=4,4,4,2,?
C DB 4 DUP(5) ; 1*4 byte, nilai awal='5'
D DB 'HAI !!' ; 6 byte berisi 6 karakter
E DW ? ; 1 word tidak diketahui isinya
F DW ?,?,? ; 3 word tidak diketahui isinya
G DW 10 DUP(?) ;10 word tidak diketahui isinya
H DD ? ; 1 DoubleWord tanpa nilai awal
I DF ?,? ; 2 FarWord tanpa nilai awal
J DQ 0A12h ; 1 QuadWord, nilai awal='0A12'
K DT 25*80 ; 1 TenBytes, nilai awal='2000'
L EQU 666 ; Konstanta, L=666
M DB '123' ; String '123'
N DB '1','2','3' ; String '123'
O DB 49,50,51 ; String '123'
Proses : ;
;
;
END Tdata
Pada baris pertama("A DB 4") kita mendefinisikan sebanyak satu byte untuk variabel dengan nama "A", variabel ini diberi nilai "4".
Pada baris kedua("B DB 4,4,4,2,?") kita mendefinisikan sebanyak 5 byte yang berpasangan untuk variabel dengan nama "B". Tiga byte pertama pada variabel "B" tersebut semuanya diberi nilai awal "4", byte ke empat diberi nilai awal 2 sedangkan byte ke lima tidak diberi nilai awal.
Pada baris ketiga("C DB 4 DUP(5)") kita mendefinisikan sebanyak 4 byte data yang diberi nilai awal "5" semuanya (DUP=Duplikasi). Jadi dengan perintah DUP kita dapat mendefinisikan suatu Array.
Pada baris keempat("D DB 'HAI !! '") kita mendefinisikan suatu string
41
dengan DB. Untuk mendefinisikan string selanjutnya akan selalu kita pakai tipe data DB. Bila kita mendefinisikan string dengan DW maka hanya 2 karakter yang dapat dimasukkan, format penempatan dalam memorypun nantinya akan membalikkan angka tersebut.
Pada baris kelima("E DW ?") kita mendefinisikan suatu tipe data Word yang tidak diberi nilai awal. Nilai yang terdapat pada variabel "E" ini bisa berupa apa saja, kita tidak perduli.
Pada baris keduabelas("L EQU 666") kita mendefinisikan suatu konstanta untuk variabel "L", jadi nilai pada "L" ini tidak dapat dirubah isinya.
Pada variabel M, N, O kita mendefinisikan suatu string "123" dalam bentuk yang berbeda. Ketiganya akan disimpan oleh assembler dalam bentuk yang sama, berupa angka 49, 50 dan 51.
Pada program-program selanjutnya akan dapat anda lihat bahwa kita selalu melompati daerah data("TData:JMP Proses"), mengapa demikian ? Bila kita tidak melompati daerah data ini maka proses akan melalui daerah data ini. Data-data program akan dianggap oleh komputer sebagai suatu intruksi yang akan dijalankan sehingga apapun mungkin bisa terjadi disana. Sebagai contohnya akan kita buat sebuah program yang tidak melompati daerah data, sehingga data akan dieksekusi sebagai intruksi. Program ini telah diatur sedemikian rupa untuk membunyikan speaker anda, pada akhir data diberi nilai CD20 yang merupakan bahasa mesin dari intruksi INT 20h.
;=====================================;
; PROGRAM : BHSMESIN.ASM ;
; AUTHOR : S’to ;
; FUNGSI : MEMBUNYIKAN SPEAKER ;
; DENGAN DATA PROGRAM ;
; ;
;======================================
.MODEL SMALL
.CODE
ORG 100h
Tdata:DB 0E4h,61h,24h,0FEh,0E6h,61h,0B9h,0D0h,7h,0BBh,9Ah
DB 2h,8Bh,0D1h,51h,34h,2h,0E6h,61h,0D1h,0C3h,73h,6h
DB 83h,0C1h,0h,0EBh,0Bh,90h,52h,2Bh,0D1h,87h,0D1h,5Ah
DB 81h,0C1h,34h,8h,0E2h,0FEh,59h,0E2h,0E2h,0CDh,20h
END Tdata
Program 9.1. Program Yang Mengeksekusi Daerah Data
9.3. PENYIMPANAN DATA DALAM MEMORY
Sebelum kita melangkah lebih jauh, marilah kita lihat dahulu bagaimana komputer menyimpan suatu nilai didalam memory. Untuk itu ketikkanlah program 42
9.2. ini yang hanya mendefinisikan data.
.MODEL SMALL
.CODE
ORG 100h
TData : JMP Proses
A DB 12h,34h
B DW 0ABCDh
C DD 56789018h
D DB 40 DUP(1)
END Tdata
Program 9.2. Mendefinisikan Data
Setelah program 9.2. diketikkan dan dijadikan COM dengan TASM.EXE dan TLINK.EXE, pakailah debug untuk melihat bagaimana data tersebut disimpan didalam memory komputer.
C:\>debug data.com A B C D
-d +-+-+ +-+-+ +----+----+ +----+--------
3001:0100 EB 31 90 12 34 CD AB 18-90 78 56 01 01 01 01 01
3001:0110 01 01 01 01 01 01 01 01-01 01 01 01 01 01 01 01
3001:0120 01 01 01 01 01 01 01 01-01 01 01 01 01 01 01 01
3001:0130 01 01 01 E0 AC 91 51 AD-8B C8 25 0F 00 8B D9 B1
3001:0140 04 D3 EB D1 E3 26 03 1E-64 01 8B 17 06 1F BF 04
3001:0150 00 57 BF FA 05 E8 83 0A-73 03 E8 63 0A 26 89 15
3001:0160 B9 FF FF EB 18 8E 06 82-01 2B DB 26 02 1C 7D 09
3001:0170 46 80 EB 80 8A FB 26 8A-1C 46 E8 16 DA 48 7D E5
-q
Gambar 9.2. Data program 9.2.
Ketiga byte pertama pada gambar 9.1. adalah bahasa mesin dari perintah "JUMP PROSES" dan "NOP". Pada byte ke 4 dan ke 5 ini adalah data dari variabel "A", dapat kita lihat bahwa data dari variabel "A"(1234) yang didefinisikan dengan "DB" disimpan didalam memory komputer sesuai dengan yang didefinisikan.
Dua byte selanjutnya(byte ke 6 dan 7), merupakan data dari variabel C yang telah kita definisikan dengan "DW(2 byte)". Ternyata kedua byte dari variabel "C"(ABCD) disimpan didalam memory dalam urutan yang terbalik(CDAB) !. Mengapa demikian ?. Hal ini dikarenakan penyimpanan dimemory yang menyimpan nilai tingginya pada alamat tinggi. Anda dapat lihat pada ke 4 byte selanjutnya, yaitu data dari variabel "D" juga disimpan dengan susunan yang terbalik(56789018 menjadi 18907856).
9.4. MENGGUNAKAN POINTER
Kini kita sudah siap untuk melihat bagaimana memindahkan data dari variabel maupun register yang berbeda tipe datanya, dengan menggunakan pointer. Untuk itu digunakan perintah PTR dengan format penulisan :
TipeData PTR operand 43
Supaya lebih jelas, marilah kita lihat penggunaanya didalam program.
;=================================;
; PROGRAM : PTR.ASM ;
; AUTHOR : S’to ;
; FUNGSI : MEMINDAHKAN DATA ;
; ANTAR TIPE DATA YANG;
; BERBEDA !!! ;
;=================================;
.MODEL SMALL
.CODE
ORG 100h
TData :
JMP Proses ; Lompat ke Proses
A DW 01EFh ; 2 Byte
B DW 02FEh ; 2 Byte
D DD ? ; 4 Byte
Proses:
MOV AL,BYTE PTR A ; AL=EF, AX=?EF
MOV AH,BYTE PTR A+1 ; AH=01, AX=01EF
MOV BX,B ; BX=02FE
MOV WORD PTR D,AX ; D=??01EF
MOV WORD PTR D+2,BX ; D=02FE01EF
INT 20h ; Kembali ke DOS
END TData
Program 9.3. Menggunakan Pointer
Pada awalnya kita mendefinisikan variabel "A" dan "B" dengan tipe data word(16 bit) yang mempunyai nilai awal 01EF dan 02FE, serta variabel "C" dengan tipe data DoubleWord(32 bit) yang tidak diinialisasi.
MOV AL,BYTE PTR A
MOV AH,BYTE PTR A+1
Pada kedua perintah tersebut, kita memindahkan data dari variabel "A" ke register AX dengan byte per byte. Perhatikanlah bahwa kita harus menyesuaikan pemindahan data yang dilakukan dengan kemampuan daya tampungnya. Oleh sebab itu digunakan "BYTE" PTR untuk memindahkan data 1 byte menuju register 8 bit, dengan demikian untuk memindahkan data 16 bit harus digunakan "WORD" PTR. Pada baris pertama kita memindahkan byte rendah dari variabel "A" (EF) menuju register AL, kemudian pada baris kedua kita memindahkan byte tingginya(01) menuju register AH. Lihatlah kita menggunakan "BYTE PTR A" untuk nilai byte rendah dan "BYTE PTR+1" untuk byte tinggi dari variabel "A" dikarenakan penyimpanan data dalam memory komputer yang menyimpan byte tinggi terlebih dahulu(Lihat bagian 9.3.).
MOV BX,B
MOV WORD PTR D,AX
44
MOV WORD PTR D+2,BX
Pada bagian ini akan kita coba untuk memindahkan data dari 2 register 16 bit menuju 1 variabel 32 bit. Pada baris pertama "MOV BX,B" tentunya tidak ada masalah karena kedua operand mempunyai daya tampung yang sama. Pada baris kedua "MOV WORD PTR D,AX" kita memindahkan nilai pada register AX untuk disimpan pada variabel "D" sebagai word rendahnya. Kemudian pada baris ketiga "MOV WORD PTR D+2,BX" kita masukkan nilai dari register BX pada variabel "D" untuk word tingginya sehingga nilainya sekarang adalah BX:AX=02FE01EF. Perhatikanlah pada baris ketiga kita melompati 2 byte(WORD PTR+2) dari variabel "D" untuk menyimpan word tingginya.
Kini dengan menggunakan pointer ini kita bisa menyimpan hasil perkalian 16 bit didalam 1 varibel 32 bit. Untuk itu lihatlah program 9.4.
;================================;
; PROGRAM : KALIPTR.ASM ;
; AUTHOR : S’to ;
; FUNGSI : MENGALIKAN BILANGAN;
; 16 BIT, HASIL ;
; PADA DX:AX ;
;================================;
.MODEL SMALL
.CODE
ORG 100h
TData :
JMP Proses ; Lompat ke Proses
A DW 01EFh ; 2 Byte
B DW 02FEh ; 2 Byte
Hsl DD ? ; 4 Byte
Proses:
MOV AX,A ; AX=1EF
MUL B ; Kalikan 1FH*2FE
MOV WORD PTR Hsl,AX ; AX bernilai C922, Hsl=??C922
MOV WORD PTR Hsl+2,DX ; DX bernilai 0005, Hsl=0005C922
INT 20h ; Kembali ke DOS
END TData
Program 9.4. Menampung nilai 2 register dalam 1 variabel
45
BAB X
MANIPULASI BIT DAN LOGIKA
10.1. GERBANG NOT
Operator NOT akan menginvers suatu nilai seperti yang terlihat pada gambar 10.1.
+-----+----------+
| A | Not (A) |
+-----+----------+
| 0 | 1 |
| 1 | 0 |
+-----+----------+
Gambar 10.1. Tabel Operator NOT
Operasi Not di dalam assembler, digunakan dengan syntax :
NOT Tujuan,Sumber
Hasil dari operasi not ini akan disimpan pada Tujuan, sebagai contoh, instruksi NOT AL,3Fh akan menghasilkan nilai C0h bagi AL. Mungkin masih ada pembaca yang bingung dengan operasi ini. Baiklah untuk lebih jelasnya kita lihat operasi di atas secara per bit.
3 F
+--+-++--+-+
Bilangan : 0011 1111
C 0
+--+-++--+-+
Not : 1100 0000
10.2. GERBANG AND
Operator AND akan menghasilkan nilai nol bila salah satu operandnya bernilai nol. Dan hanya akan bernilai satu bila kedua operandnya bernilai satu.
+-----+-----+----------+
| A | B | A AND B |
+-----+-----+----------+
| 0 | 0 | 0 |
46
| 0 | 1 | 0 |
| 1 | 0 | 0 |
| 1 | 1 | 1 |
+-----+-----+----------+
Gambar 10.2. Tabel Operator AND
Operasi AND di dalam assembler, digunakan dengan syntax :
AND Tujuan,Sumber
Hasil dari operasi AND ini akan disimpan pada Tujuan, sebagai contoh, instruksi :
MOV AL,3Fh
MOV BL,1Ah
AND AL,BL
Perintah diatas akan menghasilkan nilai 1A bagi register AL. Ingatlah :
Setiap bit yang di AND dengan 0 pasti menghasilkan bit 0 juga, sedangkan setiap bit yang di AND dengan 1 akan menghasilkan bit itu sendiri.
10.3. GERBANG OR
Operator logik OR akan menghasilkan nilai nol bila kedua operannya bernilai nol dan satu bila salah satunya bernilai satu.
+-----+-----+----------+
| A | B | A OR B |
+-----+-----+----------+
| 0 | 0 | 0 |
| 0 | 1 | 1 |
| 1 | 0 | 1 |
| 1 | 1 | 1 |
+-----+-----+----------+
Gambar 10.3. Tabel Operator OR
Operasi OR di dalam assembler, digunakan dengan syntax :
OR Tujuan,Sumber
Hasil dari operasi OR ini akan disimpan pada Tujuan, sebagai contoh, instruksi :
MOV AL,3Fh
MOV BL,1Ah
47
OR AL,BL
Hasil operasi OR diatas akan menghasilkan nilai 3F bagi register AL.
Ingatlah :
Setiap bit yang di OR dengan 0 pasti menghasilkan bit itu sendiri, sedangkan setiap bit yang di OR dengan 1 pasti menghasilkan bit 1.
10.4. GERBANG XOR
Operator XOR akan menghasilkan nol untuk dua nilai yang sama nilainya dan satu untuk yang berbeda.
+-----+-----+----------+
| A | B | A XOR B |
+-----+-----+----------+
| 0 | 0 | 0 |
| 0 | 1 | 1 |
| 1 | 0 | 1 |
| 1 | 1 | 0 |
+-----+-----+----------+
Gambar 10.4. Tabel Operator XOR
Operasi XOR di dalam assembler, digunakan dengan syntax :
XOR Tujuan,Sumber
Hasil dari operasi XOR ini akan disimpan pada Tujuan, sebagai, contoh instruksi :
MOV AX,0A12h
XOR AX,AX
Hasil operasi XOR diatas pasti akan menghasilkan nilai 0 bagi register AX.
Ingatlah: Setiap bilangan yang di XOR dengan bilangan yang sama pasti menghasilkan bilangan 0.
10.5. TEST
Perintah Test digunakan untuk mengetahui nilai pada suatu bit, dengan syntax :
TEST Operand1,Operand2
Perintah test akan mengAND kedua nilai operand, tetapi hasil yang didapatkan tidak akan berpengaruh terhadap nilai kedua operand tersebut. 48
Setelah perintah Test dilaksanakan yang akan terpengaruh adalah Flags, sehingga perintah ini sering diikuti dengan perintah yang berhubungan dengan kondisi flags. Adapun flags yang terpengaruh adalah CF,OF,PF,ZF,SF dan AF.
TEST AX,0Fh
JNZ Proses ; Lompat jika Zerro flag 0
Pada perintah diatas komputer akan menuju ke label Proses bila ada satu bit atau lebih dari AX yang sama dengan 0Fh. Bila diikuti dengan perintah JC Proses, maka komputer akan menuju ke label proses bila keempat byte rendah pada AL semuanya 1(?F).
10.6. SHL ( Shift Left )
Operator SHL akan menggeser operand1 ke kiri sebanyak operand2 secara per bit. Kemudian bit kosong yang telah tergeser di sebelah kanannya akan diberi nilai nol. Operator SHL digunakan dengan syntax :
SHL Operand1,Operand2
Supaya lebih jelas bisa anda lihat pada gambar 10.5. Operand2 harus digunakan register CL bila pergeseran yang dilakukan lebih dari satu kali.
+---------------------+
<----- | | <------ 0
+---------------------+
Gambar 10.5. Operasi SHL
Instruksi : MOV AX,3Fh
MOV CL,3
SHL AX,CL ; Geser 3 bit ke kiri
Akan menghasilkan nilai F8h pada register AX. Operasi detilnya dapat dilihat di bawah ini.
3Fh : 0011 1111
SHL 1 : 0111 1110 (=7Eh)
SHL 2 : 1111 1100 (=FCh)
SHL 3 : 1111 1000 (=F8h)
10.7. SHR ( Shift Right )
Operator SHR akan menggeser operand1 ke kanan sebanyak operand2 secara per bit dan menambahkan nilai nol pada bit yang tergeser seperti halnya pada operator SHL. Operator SHR digunakan dengan syntax :
49
SHR Operand1,Operand2
Supaya lebih jelas anda bisa lihat pada gambar 10.6. Operand2 harus digunakan register CL bila pergeseran yang dilakukan lebih dari satu kali.
+---------------------+
0 -----> | | ------>
+---------------------+
Gambar 10.6. Operasi SHR
Instruksi : MOV AX,3Fh
MOV CL,3
SHR AX,CL ; Geser 3 bit ke kanan
Akan menghasilkan nilai 07h pada register AX. Operasi detilnya dapat dilihat di bawah ini.
3Fh : 0011 1111
SHR 1 : 0001 1111 (=1Fh)
SHR 2 : 0000 1111 (=0Fh)
SHR 3 : 0000 0111 (=07h)
50
BAB XI
ADDRESSING MODES
11.1. PENDAHULUAN
Pada bab-bab sebelumnya kita telah lihat, bagaimana perintah "MOV" mengcopykan suatu nilai kepada suatu register atau variabel. Kita bisa mengcopykan nilai pada suatu register, variabel ataupun lokasi memory dengan berbagai cara. Secara umum banyaknya cara yang dapat digunakan dapat dibagi menjadi 7, seperti pada gambar 11.1.
-------------------------------------------------------------
ADDRESSING MODE FORMAT SEGMENT REGISTER
-------------------------------------------------------------
1. Immediate Data Tidak Ada
2. Register Register Tidak Ada
3. Direct Displacement DS
Label DS
4. Register Indirect [BX] DS
[BP] SS
[SI] DS
[DI] DS
5. Base Relative [BX]+Displacement DS
[BP]+Displacement SS
6. Direct Indexed [DI]+Displacement DS
[SI]+Displacement DS
7. Base Indexed [BX][SI]+Displacement DS
[BX][DI]+Displacement DS
[BP][SI]+Displacement SS
[BP][DI]+Displacement SS
------------------------------------------------------------
Gambar 11.1. Addressing Modes
Perlu anda perhatikan bahwa ada juga pengcopyan data yang terlarang, yaitu :
1. Pengcopyan data antar segment register, seperti:
MOV DS,ES
Untuk memecahkan hal ini, anda bisa menggunakan register general purpose
51
sebagai perantara, seperti:
MOV AX,ES
MOV DS,AX
Selain dengan cara diatas, anda bisa juga menggunakan stack sebagai perantara, seperti:
PUSH ES
POP DS
2. Pemberian nilai untuk segment register(DS, ES, CS, SS) secara langsung, seperti:
MOV ES,0B800h
Untuk memecahkan hal ini, anda bisa menggunakan register general purpose sebagai perantara, seperti:
MOV AX,0B800h
MOV ES,AX
3. Pengcopyan data langsung antar memory, seperti:
MOV MemB,MemA
Untuk memecahkan hal ini, anda bisa menggunakan register general purpose sebagai perantara, seperti:
MOV AX,MemA
MOV MemB,AX
4. Pengcopyan data antar register yang berbeda tipenya(8 bit dengan 16 bit) tanpa menggunakan pointer, seperti:
MOV AL,BX
Pelajarilah:
bagian ini dengan baik, karena addressing modes merupakan dasar bagi programmer bahasa assembly yang harus dikuasai.
11.2. IMMEDIATE ADDRESSING
Pengcopyan data yang tercepat ialah yang dinamakan dengan Immediate Addressing dan Register Addressing. Immediate Addressing adalah suatu pengcopyan data untuk suatu register 8,16 atau 32(80386) bit langsung dari suatu angka. Contohnya :
MOV AX,50h
MOV EAX,11223344h <80386>
Immediate Addressing dapat juga mendapatkan nilainya melalui suatu constanta yang telah didefinisikan dengan perintah EQU, seperti :
52
A EQU 67h
;
;
MOV AX,A
Perintah diatas akan mengcopykan nilai 67h untuk register AX.
11.3. REGISTER ADDRESSING
Register Addressing adalah suatu proses pengcopyan data antar register. Pengcopyan antar register ini harus digunakan register yang berukuran sama, seperti AL dan BH, CX dan AX. Contah perintahnya:
MOV AX,CX
Register Addressing dapat juga dapat juga hanya terdiri atas sebuah register seperti pada perintah INC CX.
;/========================\;
; PROGRAM : ADDR1.ASM ;
; AUTHOR : S’to ;
; FUNGSI : PERKALIAN ;
; DENGAN 80386 ;
;\========================/;
.MODEL SMALL
.386 ; Untuk prosesor 80386
.CODE
ORG 100h
Proses :
MOV EAX,12345678h ; Immediate Addressing
MOV EDX,33112244h ; Immediate Addressing
MOV EBX,EDX ; Register Addressing
MUL EBX ; Register Addressing
END Proses
Program 11.1. Perkalian pada 80386
Aturan perkalian pada pada 80386 ini sama dengan perkalian yang telah kita bicarakan didepan. Pada prosesor 80386 digunakan register-register 32 bit, seperti EAX ,EBX dan EDX pada contoh program 11.1. Untuk menggunakan kelebihan pada komputer 80386 ini kita harus menambahkan directive .386.
11.4. DIRECT ADDRESSING
Secara umum Direct Addressing ialah suatu pengcopyan data pada suatu register dan simbol.
Contoh:
53
TData : JMP Proses
A DB 12h
B DB 59h
Proses : MOV AL,A ; Direct Addressing
MOV AH,B ; Direct Addressing
Perintah diatas akan mengcopykan data variabel A dan B pada register AL dan AH.
11.5. REGISTER INDIRECT ADDRESSING
Register Indirect Addressing biasanya digunakan untuk mengakses suatu data yang banyak dengan mengambil alamat efektive dari data tersebut. Register-register yang bisa digunakan pada addressing ini adalah BX,BP,SI dan DI. Tetapi bila anda memrogram pada prosesor 80386(Dengan menambahkan directive .386) maka semua register general purpose bisa dipakai.
Untuk mendapatkan alamat efektive dari suatu data bisa digunakan perintah LEA(Load Effective Addres) dengan syntax :
LEA Reg,Data
Untuk mengakses data yang ditunjukkan oleh register Reg, setelah didapatkannya alamat efektive harus digunakan tanda kurung siku ('[]').
Jika pada perintah pengaksesannya tidak disebutkan segmennya, maka yang digunakan adalah segment default. Seperti bila digunakan register BX sebagai penunjuk offset, maka segment DS yang digunakan. Sebalikkan bila digunakan register BP sebagai penunjuk offset, maka segment SS yang digunakan.
;/=============================\;
; PROGRAM : RID.ASM ;
; AUTHOR : S’to ;
; FUNGSI : MENGAKSES DATA ;
; MELALUI ALAMAT ;
; EFEKTIVE ;
;\=============================/;
.MODEL SMALL
.CODE
ORG 100h
TData : JMP Proses
Kal DB 'ABCDEF'
Proses:
LEA BX,Kal ; Ambil Offset Kal
MOV CX,2
Ulang:
MOV DL,[BX] ; kode ASCII yang ingin dicetak
MOV AH,02h ; Nilai servis ntuk mencetak karakter
INT 21h ; Laksanakan !!
ADD BX,2 ; BX:=BX+2
LOOP Ulang ; Lompat ke Ulang
INT 20h
END TData
Program 11.2. Proses Register Indirect Addressing
Bila program 11.2. dijalankan maka dilayar anda akan tercetak :
AC
Pertama-tama kita mendefinisikan data untuk variabel 'Kal', dimana data ini nantinya akan disimpan pada memory, seperti berikut :
+-----+-----+-----+-----+-----+-----+
| A | B | C | D | E | F |
+-----+-----+-----+-----+-----+-----+
Alamat Offset: 103 104 105 106 107 108
Pada perintah LEA BX,Kal, maka register BX akan menunjuk pada alamat efektive dari variabel Kal, sebagai berikut :
BX=103
_
+-----+-----+-----+-----+-----+-----+
| A | B | C | D | E | F |
+-----+-----+-----+-----+-----+-----+
Alamat Offset: 103 104 105 106 107 108
Pada perintah MOV CX,2, kita memberikan nilai 2 kepada register CX untuk digunakan sebagai counter pada saat LOOP. Kini perhatikanlah bahwa kita mengambil nilai yang ditunjukkan oleh register BX yaitu 'A' dengan perintah MOV DL,[BX]. Tanda kurung siku menyatakan bahwa kita bukannya mengambil nilai BX tetapi nilai yang ditunjukkan oleh register BX. Setelah itu kita mencetak karakter tersebut dengan interupsi 21h servis 02 dimana kode ASCII dari karakter yang ingin dicetak telah kita masukkan pada register DL.
Pada perintah ADD BX,2 kita menambahka nilai 2 pada BX sehingga kini BX akan berjalan sebanyak 2 byte dan menunjuk pada data 'C' sebagai berikut :
BX=105
_
+-----+-----+-----+-----+-----+-----+
55
| A | B | C | D | E | F |
+-----+-----+-----+-----+-----+-----+
Alamat Offset: 103 104 105 106 107 108
Kini BX telah menunjuk pada alamat tempat data 'C' berada, sehingga pada pencetakan karakter selanjutnya, yang tercetak adalah karakter 'C'.
Ingatlah:
satu karakter menggunakan satu byte memory.
11.6. BASE RELATIVE ADDRESSING
Jenis addressing ini biasanya digunakan untuk mengakses suatu tabel dengan mengambil alamat efektivenya. Alamat efektive dari tabel tersebut nantinya digunakan sebagai patokan untuk mengakses data yang lain pada tabel tersebut. Register yang digunakan sebagai penunjuk alamat efektive ini adalah register BX,BP,SI dan DI.
;/==============================\;
; PROGRAM : BRA0.ASM ;
; AUTHOR : S’to ;
; FUNGSI : MENGAKSES DATA ;
; DENGAN BASE ;
; RELATIVE ADDRESSING;
; ;
;\==============================/;
.MODEL SMALL
.CODE
ORG 100h
TData : JMP Proses
Tabel DW 11h,50h,0Ah,14h,5Ah
Proses:
LEA BX,Tabel
MOV AX,Tabel
ADD AX,[BX]+2
ADD AX,[BX]+4
ADD AX,[BX+6]
ADD AX,[BX+8]
INT 20h
END TData
Program 11.3. Proses Base Relative Addressing
Pertama-tama kita mendefinisikan suatu tabel yang berisi data 11h,50h,0Ah,14h dan 5Ah. Data ini akan disimpan dalam memory sebagai berikut :
+------+------+------+------+------+
| 0011 | 0050 | 000A | 0014 | 005A |
+------+------+------+------+------+
56
Alamat Offset: 103 105 107 109 10A
Setelah itu kita mengambil alamat efektifnya dengan menggunakan register BX dengan perintah LEA BX,Tabel sehingga BX akan menunjuk pada alamat data yang pertama.
BX=103
_
+------+------+------+------+------+
| 0011 | 0050 | 000A | 0014 | 005A |
+------+------+------+------+------+
Alamat Offset: 103 105 107 109 10A
Dengan perintah MOV AX,Tabel maka AX akan berisi nilai pada word pertama variabel 'Tabel', yaitu 11. Dengan BX yang telah menunjuk pada data pertama(11) maka kita bisa menggunakannya sebagai patokan untuk mengakses data yang lain.
BX BX+2 BX+4 BX+6 BX+8
_ _ _ _ _
+------+------+------+------+------+
| 0011 | 0050 | 000A | 0014 | 005A |
+------+------+------+------+------+
Alamat Offset: 103 105 107 109 10A
Perlu anda perhatikan bahwa kita mengakses data yang lain terhadap BX tanpa merubah posisi dari penunjuk BX, jadi BX tetap menunjuk pada offset Tabel. Kita menambah BX dengan 2 karena data terdefinisi sebagai word(2 byte). Pada contoh program 11.3. dapat anda lihat bahwa menambah BX didalam dan diluar kurung siku adalah sama.
;/==============================\;
; PROGRAM : BRA1.ASM ;
; AUTHOR : S’to ;
; FUNGSI : MENCETAK KALIMAT ;
; DENGAN BASE ;
; RELATIVE ADDRESSING;
; ;
;\==============================/;
.MODEL SMALL
.CODE
ORG 100h
TData : JMP Proses
Kalimat DB 'NYAMUK GORENG' ; 13 karakter
Proses:
XOR BX,BX ; BX=0 Untuk penunjuk Offset
MOV CX,13 ; Counter LOOP
Ulang :
MOV DL,Kalimat[BX] ; Ambil karakter yang ke BX
MOV AH,02 ; Servis untuk cetak karakter
INT 21h ; Cetak Karakter
INC BX ; BX:=BX+1
LOOP Ulang ; Lompat ke Ulang sampai CX=0
57
INT 20h ; Selesai, kembali ke DOS !!
END TData
Program 11.4. Mencetak kalimat dengan Base Relative Addressing
Bila program 11.4. dijalankan maka dilayar akan tampak tulisan :
NYAMUK GORENG
Pada program 11.4. ini register BX dijadikan sebagai pencatat offset dari "kalimat". Dengan nilai BX sama dengan nol(0), akan menunjuk pada karakter pertama dari Kalimat(ingat! XOR dengan bilangan yang sama pasti menghasilkan 0). Setelah itu kita memberikan nilai 13 kepada CX sebagai penghitung banyaknya LOOP yang akan terjadi.
Kalimat[0] Kalimat[12]
_ _
+-+-+-+-+-+-+-+-+-+-+-+-+-+
|N|Y|A|M|U|K| |G|O|R|E|N|G|
+-+-+-+-+-+-+-+-+-+-+-+-+-+
Pada perintah MOV DL,Kalimat[BX], register BX digunakan untuk menunjukkan offset dari kalimat. Dengan demikian saat pertama kali yang dimasukkan pada register DL untuk dicetak adalah karakter 'N' kemudian BX ditambah satu sehingga BX menunjuk pada karakter 'Y'. Demikian seterusnya sampai seluruh kalimat tersebut tercetak.
11.7. DIRECT INDEXED ADDRESSING
Direct Indexed Addressing mengambil alamat efektive dari suatu data dan mengakses data dengan menggunakan register DI atau SI. Sebagai contohnya akan kita lihat tanggal dikeluarkannya ROM BIOS komputer.
Tanggal dikeluarkannya ROM BIOS pada setiap komputer terdapat pada alamat mulai F000h:FFF5h sampai F000h:FFFCh. Pada daerah ini akan terdapat 8 byte (8 huruf) yang berisi tanggal dikeluarkannya ROM BIOS. Tanggal yang tercantum menggunakan format penulisan tanggal Amerika, misalnya 04/03/73 artinya 14 Maret 1973.
;/==========================\;
; PROGRAM : VRBIOS.ASM ;
; AUTHOR : S’to ;
; FUNGSI : MELIHAT VERSI ;
; BIOS KOMPUTER ;
; ;
58
;\==========================/;
.MODEL SMALL
.CODE
ORG 100h
Proses :
MOV AX,0F000h ; Masukkan nilai F000 pada AX
MOV ES,AX ; Copykan nilai AX ke ES
MOV BX,0FFF5h ; Penunjuk Offset
XOR SI,SI ; Jadikan SI=0
MOV CX,8 ; Counter untuk LOOP
Ulang:
MOV DL,ES:[BX][SI] ; Ambil isi alamat ES:BX+SI
MOV AH,02h ; Nilai servis mencetak karakter
INT 21h ; Cetak !!
INC SI ; SI:=SI+1
LOOP Ulang ; Lompat ke Ulang sampai CX=0
INT 20h ; Selesai ! kembali ke DOS
END Proses
Program 11.5. Melihat Versi ROM BIOS
Bila program 11.5. dijalankan, maka akan ditampilkan :
18/08/94
Kita tidak bisa langsung mengisikan sebuah nilai kepada segment register, oleh karena itu digunakan register AX sebagai perantara sebagai berikut:
MOV AX,0F000h
MOV ES,AX
Setelah itu register BX yang kita gunakan sebagai penunjuk offset, diisi dengan nilai FFF5, sedangkan SI yang nantinya digunakan sebagai displacement(perpindahan) kita jadikan nol. Register CX yang digunakan sebagai counter diisi dengan 8, sesuai dengan jumlah LOOP yang dinginkan:
MOV BX,0FFF5h
XOR SI,SI
MOV CX,8
Kini kita bisa mengambil data pada alamat F000:FFF5, dengan segmnent register ES dan offset pada register BX+SI. Segment register ES ini harus dituliskan, karena bila tidak dituliskan maka segment yang digunakan adalah segment default atau segment register DS. Register SI digunakan sebagai perpindahan terhadap register BX, [BX][SI] artinya register BX+SI.
MOV DL,ES:[BX][SI]
MOV AH,02h
INT 21h
INC SI
LOOP Ulang
Proses diulangi sampai 8 karakter tanggal dikeluarkannya ROM BIOS tercetak semua.
11.8. BASED INDEXED ADDRESSING
Jenis addressing ini biasanya digunakan untuk mengakses suatu record 59
atau suatu array 2 dimensi.
;/===============================\;
; PROGRAM : BIA.ASM ;
; AUTHOR : S’to ;
; FUNGSI : MENGAKSES ARRAY ;
; DENGAN BASE ;
; INDEXED ADDRESSING ;
;\===============================/;
.MODEL SMALL
.CODE
ORG 100h
TData : JMP Proses
Mahasiswa STRUC
Nim DW 0 ; 2 byte
Tinggi DB 0 ; 1 byte
Nilai DB 0,0,0,0 ; 4 byte
Mahasiswa ENDS
Absen Mahasiswa 10 DUP (<>)
Proses:
LEA BX,Absen ; BX Menunjuk Offset Absen
ADD BX,21 ; BX Menunjuk pada Record ke 4
XOR SI,SI ; SI=0
MOV [BX][SI].Nim ,0099h ; NIM, record ke 4
MOV [BX][SI].Tinggi ,10h ; Tinggi, record ke 4
MOV [BX][SI+1].Nilai,78h ; Nilai pertama
MOV [BX][SI+2].Nilai,99h ; Nilai kedua
MOV [BX][SI+3].Nilai,50h ; Nilai keempat
MOV [BX][SI+4].Nilai,83h ; Nilai kelima
INT 20h ; Selesai !!
END TData
Program 11.6. Teknik Mengakses Record
Pada program 11.6. akan kita lihat bagaimana based indexed addressding memudahkan kita dalam mengakses suatu array record.
Mahasiswa STRUC
Nim DW ?
Tinggi DB ?
Nilai DB ?,?,?,?
Mahasiswa ENDS
Absen Mahasiswa 10 DUP (<>)
Perintah "STRUC" digunakan untuk mendefinisikan suatu record dan diakhiri dengan "ENDS". Field-field yang kita definisikan untuk record mahasiswa ini adalah 2 byte untuk NIM, 1 byte untuk Tinggi, 4 byte untuk Nilai. Jadi besar satu record adalah 7 byte. Pada baris selanjutnya kita mendefinisikan 10 buah record mahasiwa dengan perintah DUP. Tanda cryptic
60
"(<>)" digunakan untuk menginialisasi nilai pada array menjadi nol.
ADD BX,21
XOR SI,SI
Pada contoh program ini kita akan memasukan data pada record ke 4, dan karena 1 record menggunakan 7 byte, maka BX kita tambah dengan 21 supaya BX menunjuk pada record ke 4. Register SI yang nantinya kita gunakan sebagai perpindahan dijadikan 0.
MOV [BX][SI].Nim ,0099h
MOV [BX][SI].Tinggi ,10h
Dengan BX yang telah menunjuk pada record ke 4, maka kita bisa langsung memasukkan nilai untuk NIM dan Tinggi pada record ke 4.
MOV [BX][SI].Nilai ,78h
MOV [BX][SI+1].Nilai,99h
MOV [BX][SI+2].Nilai,50h
MOV [BX][SI+3].Nilai,83h
Kini perhatikanlah bahwa dalam memasukkan angka untuk variabel "nilai" yang mempunyai 4 byte bisa kita gunakan register SI sebagai perpindahan. "MOV [BX][SI]" akan menunjuk pada byte pertama untuk variabel nilai sedangkan "[BX][SI+1]" akan menunjuk pada byte kedua untuk variabel nilai, demikianlah seterusnya. Mudah Bukan ?.
61
BAB XII
MENCETAK KALIMAT
12.1. MENCETAK KALIMAT DENGAN FUNGSI DOS
Untuk mencetak kalimat, bisa digunakan interupsi 21 fungsi 9 dengan aturan:
INPUT
AH = 9
DS:DX = Alamat String tersebut
CATATAN = Karakter '$' dijadikan tanda akhir tulisan
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~;
; Program: kal0.asm ;
; Oleh : S’to ;
; Fungsi : Mencetak String ;
; dengan Int 21 servis 9 ;
;=====================================;
.MODEL SMALL
.CODE
ORG 100h
Tdata : JMP Proses
Kal0 DB 'PROSES PENCETAKAN STRING ',13,10,'$'
Kal1 DB 'DIBELAKANG TANDA $ TIDAK BISA DICETAK '
Proses:
MOV AH,09h ; Servis ke 9
MOV DX,OFFSET Kal0 ; Ambil Alamat Offset Kal0
INT 21h ; Cetak perkarakter sampai tanda $
LEA DX,Kal0 ; Ambil Alamat Offset Kal0
INT 21h ; Cetak perkarakter sampai tanda $
LEA DX,Kal0+7 ; Ambil Alamat Offset KAl0+7
INT 21h ; Cetak perkarakter sampai tanda $
LEA DX,KAL1 ; Ambil Offset kal1
INT 21h ; Cetak perkarakter sampai ketemu $
INT 20h ; Selesai, kembali ke DOS
END Tdata
Program 12.1. Mencetak kalimat dengan fungsi DOS
Pada saat program 12.1. anda jalankan, maka dilayar akan ditampilkan:
PROSES PENCETAKAN STRING
DIBELAKANG TANDA
Pada saat pendefinisian untuk variabel "KAL0" kita menambahkan tanda 13 dan 10. Kedua tanda ini merupakan karakter kontrol untuk pindah baris(tanda 10) dan menuju kolom 0(tanda 13). Pada akhir dari setiap kalimat yang ingin dicetak harus kita tambahkan dengan karakter "$". Karakter ini akan dipakai
62
sebagai tanda akhir dari kalimat.
Karena karakter "$" dijadikan sebagai tanda akhir dari kalimat yang ingin dicetak, maka pada proses pencetakan karakter yang kedua hanya kalimat "DIBELAKANG TANDA" yang tercetak. Sisa kalimatnya, yaitu "TIDAK BISA DICETAK" tidak tercetak keluar, karena terletak dibelakang tanda "$".
Dengan demikian, bila kita ingin mencetak kalimat yang mengandung tanda "$", harus digunakan fungsi yang lain, misalnya mencetak kalimat dengan perkarakter melalui interupsi 21 fungsi 2.
12.2. KARAKTER KONTROL
Pada program 12.1. kita telah menggunakan 2 buah karakter kontrol, yaitu 10(LF) dan 13(CR). Karakter kontrol yang tersedia untuk operasi pada video yang sering digunakan terdapat 5, yaitu 07, 08, 09, 10 dan 13(Gambar 12.1).
----------------------------------------------------------------
CODE NAMA FUNGSI
----------------------------------------------------------------
07 Bel Memberikan suara BEEP
08 Backspace(BS) Memindahkan kursor 1 kolom ke belakang
09 Horisontal Tab Memindahkan kursor 8 kolom ke kanan
10 Line Feed(LF) Memindahkan kursor 1 baris ke bawah
13 Carriage Return(CR) Memindahkan kursor menuju awal baris
----------------------------------------------------------------
Gambar 12.1. Karakter Kontrol Yang Sering Digunakan
Selain dari karakter kontrol pada gambar 12.1, masih terdapat karakter-karakter kontrol lain, yang sebagian besar digunakan untuk keperluan komunikasi komputer dengan periferalnya. Karakter kontrol yang tersedia pada ASCII secara lengkap bisa anda lihat pada gambar 12.2.
-----------------------------+----------------------------------
CODE NAMA | CODE NAMA
-----------------------------+----------------------------------
00 Nul | 16 Data Link Escape
01 Start Of Heading | 17 Device Control
02 Start Of Text | 18 Negative Acknowledge
03 End Of Text | 19 Synchronous Idle
04 End Of Transmission | 20 End Of Transmission Block
05 Enquiry | 21 Cancel
63
06 Acknowledge | 22 End Of Medium
07 Bel | 23 Substitute
08 Backspace | 24 Escape
09 Horisontal Tabulation| 25 File Separator
10 Line Feed | 26 Group Separator
11 Vertical Tabulation | 27 Record Separator
12 Form Feed | 28 Unit Separator
13 Carriage Return | 29 Space
14 Shift Out | 30 Delete
15 Shift In |
-----------------------------+----------------------------------
Gambar 12.2. Karakter Kontrol Pada ASCII
12.3. MENCETAK KALIMAT DENGAN ATRIBUTNYA
Pada bagian sebelumnya kita mencetak kalimat dengan fungsi DOS yang mencetak kalimat tanpa atribut. Untuk mencetak kalimat dengan atributnya bisa digunakan fungsi dari BIOS, melalui interupsi 10h. Adapun yang harus anda persiapkan adalah: register AX diisi dengan 1300h, BL diisi dengan atribut yang ingin ditampilkan, BH diisi dengan halaman tampilan, DL diisi dengan posisi X tempat kalimat tersebut akan tercetak sedangkan DH diisi dengan posisi Y-nya. Karena fungsi ini tidak mengenal batas tulisan "$" seperti interupsi 21h servis 9, maka kita harus mengisikan CX dengan banyaknya karakter dalam kalimat. Register ES:BP digunakan untuk mencatat alamat dari kalimat yang ingin dicetak.
;/=============================================\;
; Program : ATTR-KLM.ASM ;
; Author : S’to ;
; Fungsi : Mencetak kalimat disertai ;
; atributnya ;
;-----------------------------------------------;
; INT 10h ;
;-----------------------------------------------;
; Input : ;
; AX = 1300h ;
; BL = Atribut ;
; BH = Halaman tampilan ;
; DL = Posisi X ;
; DH = Posisi Y ;
; CX = Panjang kalimat
; ES:BP = Alamat awal string ;
; ;
;\=============================================/;
.MODEL SMALL
.CODE
ORG 100h
TData : JMP Proses
64
Kal0 DB ' Menulis kalimat dengan Atributnya '
Proses:
MOV AX,1300h ; Servis 13h subfungsi 00
MOV BL,10010101b ; Atribut tulisan
MOV BH,00 ; Halaman tampilan 0
MOV DL,20 ; Posisi X
MOV DH,12 ; Posisi Y
MOV CX,35 ; Banyaknya karakter dalam string
LEA BP,Kal0 ; ES:BP alamat string
INT 10h ; Cetak kalimat !
INT 20h ; Selesai, kembali ke DOS
END TData
Program 12.2. Mencetak Kalimat Dengan Atributnya
Bila program 12.2. dijalankan, maka layar pada posisi kolom ke 20 dan baris ke 12 akan terdapat tulisan:
Menulis kalimat dengan Atributnya
Tulisan ditampilkan dengan warna tulisan putih dan warna dasar jingga. Mengenai halaman layar akan dibahas pada bagian yang lain, sedangkan mengenai atribut akan segera kita bahas.
12.4. PENGATURAN ATRIBUT
Atribut atau warna menggunakan 1 byte memory, yang akan menandakan warna tulisan dan warna dasar dari karakter yang akan tercetak. Byte atribut ini digunakan dengan masing-masing bitnya, dimana setiap bit mencatat warnanya masing-masing. Adapun spesifikasinya adalah:
Warna Dasar Warna Tulisan
+----+----+ +----+----+
Bit-ke 7 6 5 4 3 2 1 0
_ _ _ _ _ _ _ _
BL R G B I R G B
Catatan: BL = Blink atau berkedip
R = Merah
G = Hijau
B = Biru
I = Intensitas warna
Untuk menghidupkan warna yang diinginkan anda tinggal menjadikan bit tersebut menjadi satu. Sebagai contohnya bila anda menginginkan warna tulisan Biru dengan warna dasar Hijau, maka anda tinggal menghidupkan bit ke 0 dan 5 atau dengan angka 00100001b(21h). Untuk menjadikannya berintensitas tinggi dan berkedip anda juga tinggal menjadikan bit ke 3 dan 7 menjadi satu(10101001b).
Bila anda menghidupkan bit ke 0,1 dan 2 menjadi satu dan mematikan bit-bit lainnya maka anda akan mendapatkan campuran dari ketiga warna tersebut(Putih) untuk warna tulisan dan warna hitam untuk warna dasar. Inilah 65
warna normal yang biasa digunakan, yaitu warna dengan atribut 7.
66
BAB XIII
BANDINGKAN DAN LOMPAT
13.1. LOMPAT TANPA SYARAT
Perintah JMP(Jump), sudah pernah kita gunakan, dimana perintah ini digunakan untuk melompati daerah data program. Perintah JMP digunakan dengan syntax:
JMP Tujuan
Perintah JMP ini dikategorikan sebagai Unconditional Jump, karena perintah ini tidak menyeleksi keadaan apapun untuk melakukan suatu lompatan. Setiap ditemui perintah ini maka lompatan pasti dilakukan.
Selain dari perintah jump tanpa syarat, masih banyak perintah Jump yang menyeleksi suatu keadaan tertentu sebelum dilakukan lompatan. Perintah jump dengan penyeleksian kondisi terlebih dahulu biasanya diikuti dengan perintah untuk melihat kondisi, seperti membandingkan dengan perintah "CMP"(Compare).
13.2. MEMBANDINGKAN DENGAN CMP
Perintah CMP(Compare) digunakan untuk membandingkan 2 buah operand, dengan syntax:
CMP Operand1,Operand2
CMP akan membandingkan operand1 dengan operand2 dengan cara mengurangkan operand1 dengan operand2. CMP tidak mempengaruhi nilai Operand1 dan Operand2, perintah CMP hanya akan mempengaruhi flags register sebagai hasil perbandingan. Adapun flag-flag yang terpengaruh oleh perintah CMP ini adalah:
- OF akan 1, jika operand1 lebih kecil dari operand2 pada operasi
bilangan bertanda.
- SF akan 1, bila operand1 lebih kecil dari operand2, pada operasi
bilangan bertanda.
- ZF akan 1, jika operand1 nilainya sama dengan operand2.
- CF akan 1, jika operand1 lebih kecil dari operand2 pada operasi
bilangan tidak bertanda.
Perlu anda ingat bahwa CMP tidak dapat membandingkan antar 2 lokasi memory.
13.3. LOMPAT YANG MENGIKUTI CMP
Perintah CMP yang hanya mempengaruhi flag register, biasanya diikuti dengan perintah lompat yang melihat keadaan pada flags register ini. Jenis perintah lompat yang biasanya mengikuti perintah CMP, terdapat 12 buah seperti pada gambar 13.1.
-----------------------------+----------------------------------
Perintah Lompat | Kondisi
-----------------------------+----------------------------------
JA
| untuk bilangan tidak bertanda
JG
67
| untuk bilangan bertanda
JE
JNE
| dengan Operand2
JB
| untuk bilangan tidak bertanda
JL
| untuk bilangan bertanda
JBE
| untuk bilangan tidak bertanda
JLE
| untuk bilangan bertanda
JAE
| untuk bilangan tidak bertanda
JGE
Equal> | untuk bilangan bertanda
-----------------------------+----------------------------------
Gambar 13.1. Perintah Jump yang mengikuti CMP
Pada tabel 13.1. dapat anda lihat bahwa terdapat dua operasi yang berbeda, yaitu operasi bilangan bertanda dan tidak bertanda. Bilangan bertanda adalah bilangan yang akan membedakan bilangan negatif dan positif(Mis. 37 dan -37). Sedangkan bilangan tidak bertanda adalah bilangan yang tidak akan membedakan positif dan negatif, jadi angka -1 untuk operasi bilangan bertanda akan dianggap FFh pada bilangan tidak bertanda. Lebih jauh mengenai bilangan bertanda dan tidak ini bisa anda lihat pada bab1.
;/=========================================\;
; Program : CMPJ.ASM ;
; Author : S’to ;
; Fungsi : Mendemokan perintah lompat ;
; yang mengikuti perintah CMP ;
; ;
;\=========================================/;
.MODEL SMALL
.CODE
ORG 100h
TData: JMP Proses
BilA DB 67
BilB DB 66
Kal0 DB 'Bilangan A lebih kecil dari bilangan B $'
Kal1 DB 'Bilangan A sama dengan bilangan B $'
Kal2 DB 'Bilangan A lebih besar dari bilangan B $'
Proses:
MOV AL,BilA ; Masukkan bilangan A pada AL
CMP AL,BilB ; Bandingkan AL(BilA) dengan Bilangan B
JB AKecil ; Jika BilA < BilB, lompat ke AKecil
JE Sama ; Jika BilA = BilB, lompat ke Sama
JA ABesar ; Jika BilA > BilB, lompat ke ABesar
Akecil:
68
LEA DX,Kal0 ; Ambil offset Kal0
JMP Cetak ; Lompat ke cetak
Sama:
LEA DX,Kal1 ; Ambil offset Kal1
JMP Cetak ; Lompat ke cetak
ABesar:
LEA DX,Kal2 ; Ambil offset Kal2
Cetak:
MOV AH,09 ; Servis untuk mencetak kalimat
INT 21h ; Cetak kalimat !!
EXIT: INT 20h ; Kembali ke DOS.
END TData
Program 13.1. Menggunakan Perintah Lompat Bersyarat
Bila program 13.1. dijalankan, maka akan tampak pada layar:
Bilangan A lebih besar dari bilangan B
Anda bisa mengganti nilai pada variabel BilA dan BilB untuk melihat hasil yang akan ditampilkan pada layar.
13.4. LOMPAT BERSYARAT
Pada gambar 13.1. anda telah melihat sebagian dari perintah lompat bersyarat. Kini akan kita lihat lompat bersyarat lainnya yang tersedia, seperti pada gambar 13.2. Tidak seperti lompat tanpa syarat, Lompat bersyarat hanya dapat melompat menuju label yang berjarak -128 sampai +127 byte dari tempat lompatan.
-----------------------------+----------------------------------
Perintah Lompat | Kondisi
-----------------------------+----------------------------------
JA
| untuk bilangan tidak bertanda
JG
| untuk bilangan bertanda
JE
JNE
| dengan Operand2
JB
| untuk bilangan tidak bertanda
JL
| untuk bilangan bertanda
JBE
| untuk bilangan tidak bertanda
JLE
| untuk bilangan bertanda
JAE
| untuk bilangan tidak bertanda
JGE
Equal> | untuk bilangan bertanda
JC
69
JCXZ
JNA
| dengan CF=1 atau ZF=1
JNAE
JNB
| dengan CF=0
JNBE
Equal> | dengan CF=0 dan ZF=0
JNC
JNG
| dengan ZF=1 atau SF tidak sama OF
JNGE
JNL
| dengan SF=OF
JNLE
Nor Equal> | dengan ZF=0 dan SF=OF
JNO
| tidak terjadi Overflow
JNP
JNS
JNZ
JO
JP
JPE
JPO
JS
JZ
-----------------------------+----------------------------------
Gambar 13.2. Daftar Perintah Jump
Bila dilihat pada daftar 13.2., perintah untuk lompat sebenarnya sangat mudah untuk digunakan karena setiap huruf melambangkan suatu kata. Dengan demikian kita tidak perlu untuk mengingat-ingat semua perintah diatas, kita hanya harus ingat bahwa huruf J=Jump, E=Equal, N=Not, S=Sign, Z=Zero, P=Parity, O=Overflow, C=Carry, G=Greater Than, A=Above, L=Less dan B=Below.
Ingatlah:
Huruf G dan L yang artinya Greater Than dan Less digunakan khusus untuk operasi bilangan bertanda. Sedangkan Huruf A dan B yang artinya Above dan Below digunakan khusus untuk operasi bilangan tidak bertanda.
;/================================================\;
; Program : JMPL.ASM ;
; Author : S’to ;
70
; Fungsi : Mencetak kalimat secara perkarakter ;
; sampai ditemui karakter '*' ;
; ;
;\================================================/;
.MODEL SMALL
.CODE
ORG 100h
TData : JMP Proses
Kal DB ' Lucky Luck menembak ',13,10
DB 'Lebih cepat dari bayangannya !! ',7,7,'*'
Proses:
XOR BX,BX ; BX=0
MOV AH,02h ; Servis Untuk Cetak Karakter
Ulang:
CMP Kal[BX],'*' ; Bandingkan dengan '*'
JE Exit ; Jika Sama Lompat ke Exit
MOV DL,Kal[BX] ; Masukkan karakter ke BX menuju DL
INT 21h ; Cetak karakter
INC BX ; Tambah 1 pada BX
JMP Ulang ; Lompat Ke Ulang
Exit : INT 20h ; Selesai ! kembali ke DOS
END TData
Program 13.2. Perbandingan
Bila program 13.2. dijalankan, maka pada layar akan ditampilkan:
Lucky Luck menembak
Lebih cepat dari bayangannya !!
Angka 7 pada akhir kalimat digunakan untuk menghasilkan suara beep. Bila anda masih ingat pada addressing yang telah kita pelajari, maka program 13.2. tentunya tidak ada masalah.
71
BAB XIV
STACK
14.1. APA ITU STACK ?
Bila kita terjemahkan secara bebas, stack artinya adalah 'tumpukan'. Stack adalah bagian memory yang digunakan untuk menyimpan nilai dari suatu register untuk sementara. Operasi- operasi pada assembler yang langsung menggunakan stack misalnya pada perintah PUSH, POP, PUSF dan POPF.
Pada program COM yang hanya terdiri atas satu segment, dimanakah letak dari memory yang digunakan untuk stack ?. Seperti pasangan CS:IP yang menunjukkan lokasi dari perintah selanjutnya yang akan dieksekusi, pada stack digunakan pasangan SS:SP untuk menunjukkan lokasi dari stack. Untuk itu marilah kita lihat dengan debug:
C:\>debug
-r
AX=0000 BX=0000 CX=0000 DX=0000 SP=FFEE BP=0000 SI=0000 DI=0000
DS=3143 ES=3143 SS=3143 CS=3143 IP=0100 NV UP EI PL NZ NA PO NC
3143:0100 0F DB 0F
-q
Dari percobaan ini dapat kita lihat bahwa SS menunjukkan angka yang sama dengan CS(3143) atau dengan kata lain CS dan SS berada pada satu segment. Register IP yang menunjukkan lokasi stack bernilai FFFE atau dengan kata lain stack terletak pada akhir segment. Karena inilah pada program COM sebaiknya anda jangan sembarangan mengubah data pada akhir segment, karena hal ini akan mengacaukan program. Bila kita gambarkan letak dari stack akan tampak seperti gambar 14.1
+--------------+
| Letak Dari |
CS:IP_| Program |
| |
+--------------+
| Area Kosong |
SS:SP_+--------------+
| Tempat Stack |
+--------------+
Gambar 14.1. Lokasi Stack 72
14.2. CARA KERJA STACK
Seperti yang telah dikatakan, bahwa stack digunakan sebagai tempat penampung sementara nilai dari suatu register. Supaya lebih jelas lihatlah cara kerja dari program 14.1.
;/=========================================\;
; Program : NSTACK.ASM ;
; Author : S’to ;
; Fungsi : Mencetak kalimat 2 kali ;
; dengan operasi yang mirip ;
; dengan stack ;
;\=========================================/;
.MODEL SMALL
.CODE
ORG 100h
TData : JMP Proses
Kal DB 'LANG LING LUNG $'
Ganti DB 13,10,'$'
Stacks DW ?
Proses:
LEA DX,Kal
MOV Stacks,DX
MOV AH,09
INT 21h
LEA DX,Ganti
INT 21h
MOV DX,Stacks
INT 21h
Exit : INT 20h
END TData
Program 14.1. Mencetak kalimat 2 kali
Bila program 14.1. dan 14.2. dijalankan, maka pada layar akan ditampilkan:
LANG LING LUNG
LANG LING LUNG
Perhatikanlah, perintah:
LEA DX,Kal
MOV Stacks,DX
Pada baris pertama kita mendapatkan alamat efektif dari "Kal" dan disimpan pada DX. Kemudian kita simpan nilai DX yang menunjuk pada offset "Kal" ini pada variabel Stacks. Sehingga pada saat kita hendak mencetak 'Kal' untuk kedua kalinya, kita tinggal mengambil nilai dari variabel Stacks dengan perintah "MOV DX,Stacks".
Kini akan kita lihat bagaimana menggunakan stack yang sebenarnya untuk 73
tugas ini.
;/=========================================\;
; Program : STACK.ASM ;
; Author : S’to ;
; Fungsi : Mencetak kalimat 2 kali ;
; dengan operasi stack yang ;
; sebenarnya ;
;\=========================================/;
.MODEL SMALL
.CODE
ORG 100h
TData : JMP Proses
Kal DB 'LANG LING LUNG $'
Ganti DB 13,10,'$'
Stacks DW ?
Proses:
LEA DX,Kal
PUSH DX
MOV AH,09
INT 21h
LEA DX,Ganti
INT 21h
POP DX
INT 21h
Exit : INT 20h
END TData
Program 14.2. Operasi Stack
Dengan perintah "PUSH", kita menyimpan nilai register DX pada stack, kemudian pada perintah "POP" kita mangambil keluar nilai yang disimpan tersebut dari stack. Dari program ini dapat dilihat bagaimana stack menggantikan varibel pada program 14.1. yang digunakan untuk menyimpan nilai pada register DX.
Kini lihatlah bagaimana program yang menggunakan pengulangan didalam pengulangan dengan memanfaatkan stack ini. Dalam bahasa Pascal programnya akan tampak seperti berikut:
For i:= 10 DownTo 1 Do
For j:= 5 DownTo 1 Do
For s:= 3 DownTo 1 Do
Begin
End
Dalam bahasa assembler akan tampak seperti:
MOV CX,10
i:
PUSH CX
MOV CX,5
74
j:
PUSH CX
MOV CX,3
s:
LOOP s
POP CX
LOOP j
POP CX
LOOP i
14.3. PUSH DAN POP
Stack dapat kita bayangkan sebagai sebuah tabung yang panjang. Sedangkan nilai pada register dapat dibayangkan berbentuk koin yang dapat dimasukkan dalam tabung tersebut.
Untuk memasukkan nilai suatu register pada stack, digunakan perintah push dengan syntax:
PUSH Reg16Bit
Sebagai contohnya pada perintah:
MOV AX,12
MOV BX,33
MOV CX,99
PUSH AX ; Simpan nilai AX pada stack
PUSH BX ; Simpan nilai BX pada stack
PUSH CX ; Simpan nilai CX pada stack
Maka pada stack akan tampak seperti:
<<<<>>>>>
Gambar 14.2. Penyimpanan Nilai Pada Stack
Dari gambar 14.2. dapat anda lihat bahwa nilai yang terakhir dimasukkan(99) akan terletak pada puncak tabung stack.
Untuk mengambil keluar koin nilai pada tabung stack, digunakan perintah pop dengan syntax:
POP Reg16Bit
Perintah POP akan mengambil koin nilai pada stack yang paling atas dan dimasukkan pada Reg16Bit. Dari sini dapat anda lihat bahwa data yang terakhir dimasukkan akan merupakan yang pertama dikeluarkan. Inilah sebabnya operasi stack dinamankan LIFO(Last In First Out).
Sebagai contohnya, untuk mengambil nilai dari register AX, BX dan CX yang disimpan pada stack harus dilakukan pada register CX dahulu barulah BX dan AX, seperti:
POP CX ; Ambil nilai pada puncak stack, masukkan ke CX
POP BX ; Ambil nilai pada puncak stack, masukkan ke BX
POP AX ; Ambil nilai pada puncak stack, masukkan ke AX
Perhatikan: 75
Bila anda terbalik dalam mengambil nilai pada stack dengan POP AX kemudian POP BX dan POP CX, maka nilai yang akan anda dapatkan pada register AX, BX dan CX akan terbalik. Sehingga register AX akan bernilai 99 dan CX akan bernilai 12.
TRIK:
Seperti yang telah kita ketahui, data tidak bisa dicopykan antar segment atau memory. Untuk mengcopykan data antar segment atau memory anda harus menggunakan register general purpose sebagai perantaranya, seperti:
MOV AX,ES ; Untuk menyamakan register
MOV DS,AX ; ES dan DS
Dengan adanya stack, anda bisa menggunakannya sebagai perantara, sehingga akan tampak seperti:
PUSH ES ; Untuk menyamakan register
POP DS ; ES dan DS
14.4. PUSF DAN POPF
PUSF dan POPF, sama halnya dengan perintah PUSH dan POP. Perintah PUSF digunakan untuk menyimpan nilai dari flags register pada stack sedangkan POPF digunakan untuk mengambil nilai pada stack dan disimpan pada flags register. Kedua perintah ini digunakan tanpa operand:
PUSHF ; Simpan nilai Flags pada stack
POPF ; Ambil nilai pada stack
Perintah PUSHF dan POPF digunakan untuk menyelamatkan kondisi dari flag terhadap perubahan. PUSHF dan POPF biasanya digunakan pada operasi yang sangat mementingkan nilai pada flag ini, seperti pada operasi aritmatika.
76
BAB XV
MASUKAN DARI KEYBOARD
Keyboard merupakan sarana bagi kita untuk berkomunikasi dengan program. Pada bagian ini akan kita lihat bagaimana caranya untuk menanggapi masukan dari keyboard. Tetapi sebelumnnya anda tentunya harus mengerti sedikit mengenai beberapa hal penting yang berkaitan dengan keyboard itu.
15.1. KODE SCAN DAN ASCII
Prosesor pada keyboard mendeteksi setiap penekanan maupun pelepasan tombol pada keyboard. Prosesor ini menterjemahkan setiap sinyal yang terjadi berdasarkan posisi tertentu menjadi apa yang dinamakan kode Scan. Dengan demikian tombol "A" dan "B" akan mempunyai kode Scan yang berbeda karena posisinya memang berbeda. Lain halnya untuk tombol "A" dan "a" yang terdapat pada posisi yang sama, akan mempunyai kode Scan yang sama. Kode Scan ini biasanya tidak berguna bagi kita. Kita biasanya hanya menggunakan kode ASCII dan Extended yang merupakan hasil terjemahan dari kode scan oleh keyboard handler.
Kode ASCII adalah kode yang melambangkan suatu karakter baik berupa huruf,angka, maupun simbol-simbol grafik. Misalkan angka "1" akan dilambangkan dengan kode ASCII 49. Untuk kode ASCII ini bisa anda lihat pada lampiran.
15.2 APA ITU KODE EXTENDED ?
Kode ASCII telah menyediakan sebanyak 256 karakter dengan beberapa karakter kontrol, misalnya #10 untuk pindah baris dan #13 untuk Enter yang akan menggerakkan kursor kesamping kiri. Tetapi fungsi yang telah disediakan ini tidak mampu untuk menampilkan ataupun mendeteksi tombol fungsi misalnya F1, F2, F3 dan Home. Tombol kombisasi juga tidak dapat dideteksi oleh karakter ASCII , misalnya penekan tombol shif disertai tombol F1, penekanan Ctrl disertai tombol Home, dan lain-lain. Penekanan terhadap tombol-tombol fungsi dan tombol kombinasi akan menghasilkan kode ASCII 0
Karena alasan diatas maka diciptakanlah suatu kode yang dinamakan sebagai kode EXTENDED. Kode Extended ini dapat mendeteksi penekanan terhadap tombol-tombol fungsi maupun tombol kombinasi. Untuk kode extended bisa anda lihat pada lampiran.
15.3. MASUKAN SATU KARAKTER
Interupsi dari BIOS, yaitu interupsi 16h servis 0 dapat digunakan untuk mendapatkan masukan satu karakter dari keyboard.
Hasil dari pembacaan karakter fungsi ini akan diletakkan pada register AX. Bila terjadi penekanan pada tombol biasa maka byte rendah dari AX
Bila yang ditekan adalah tombol khusus(extended) yang akan menghasilkan kode ASCII 0 maka byte rendah dari register AX
tersebut.
;/========================================\;
; Program : READKEY.ASM ;
; Author : S’to ;
; Fungsi : Input satu karakter ;
; dari keyboard. ;
;==========================================;
; INTERUPSI 16h ;
;==========================================;
; Input: OutPut: ;
; AH = 0 Jika tombol biasa, maka: ;
; AL = ASCII ;
; AH = SCAN ;
; ;
; Jika Tombol khusus, maka ;
; AL = 00 ;
; AH = Extended ;
; ;
;\========================================/;
.MODEL SMALL
.CODE
ORG 100h
TData : JMP Proses
T_ASCII DB 13,10,'Ini adalah tombol ASCII : $'
T_Extended DB 13,10,'Ini adalah tombol Extended $'
Proses :
MOV AH,0 ; Servis Input satu karakter
INT 16h ; Laksanakan
PUSH AX ; Simpan hasil pembacaan pada stack
CMP AL,00 ; Apakah ini karakter extended ?
JE Extended ; Ya !, Lompat ke Extended
ASCII:
LEA DX,T_ASCII ; Ambil alamat efektif T_ASCII
MOV AH,09 ; Servis cetak kalimat
INT 21h ; Cetak kalimat !
POP AX ; Ambil kembali nilai AX pada stack
MOV DL,AL ; Ambil kode ASCII yang ditekan
MOV AH,2 ; Servis cetak karakter
INT 21h ; Cetak karakter !
CMP AL,'Q' ; Apakah yang ditekan huruf 'Q' ?
JE exit ; Ya !, lompat ke Exit
CMP AL,'q' ; Apakah yang ditekan huruf 'q' ?
JE exit ; Ya !, lompat ke Exit
JMP Proses ; Lompat ke Proses
Extended:
LEA DX,T_Extended ; Ambil alamat efektif T_Extended
MOV AH,09 ; Servis cetak kalimat
INT 21h ; Cetak kalimat !
JMP Proses ; Lompat ke Proses
exit: INT 20h ; Kembali ke DOS !
END TData
Program 15.1. Menunggu masukan satu karakter dari Keyboard
Bila anda menekan tombol extended, seperti penekanan tombol anak panah, F1, F2 dan sebagainya maka pada layar akan ditampilkan :
78
F1, F2 dan sebagainya maka pada layar akan ditampilkan :
78
Ini adalah tombol Extended
Bila anda ingin mengetahui lebih lanjut mengenai tombol apa yang ditekan maka kode extendednya bisa dilihat pada register AH. Sedangkan bila yang ditekan adalah tombol biasa, seperti huruf 'S' maka pada layar akan ditampilkan:
Ini adalah tombol ASCII : S
Program akan selesai jika anda menekan tombol "q" atau "Q".
15.4. MENDETEKSI PENEKANAN SEMBARANG TOMBOL
Dengan fungsi 11h dari interupsi 16h, kita bisa mendeteksi terhadap penekanan tombol,sama halnya seperti yang dilakukan oleh fungsi keypressed pada bahasa pascal. Fungsi ini akan mendeteksi keyboard buffer, bila pada keyboard buffer terdapat suatu tombol maka ia akan membuat zerro flags menjadi nol<0> dan register AL berisi kode ASCII dari karakter tersebut sedangkan register AH akan berisi kode Scan dari tombol tersebut. Sebaliknya jika pada keyboard buffer tidak ada karakter maka zerro flags akan bernilai satu <1>.
Keyboard buffer adalah suatu penampung yang digunakan untuk menampung setiap penekanan tombol pada keybaord. Daya tampung normal dari keyboard buffer adalah 15 karakter. Jika keyboard buffer telah penuh, speaker akan mengeluarkan tanda berupa suara beep.
;/=============================================\;
; Program : KEYPRESS.ASM ;
; Author : S’to ;
; Fungsi : Mengecek apakah ada ;
; tombol yang ditekan ;
;===============================================;
; INTERUPSI 16h ;
;===============================================;
; Input: OutPut: ;
; AH = 1 Jika Ada tombol yang ditekan ;
; ZF = 0 dan ;
; AL = kode ASCII ;
; AH = Scan Code ;
; ;
; Jika Tidak ada penekanan Tombol ;
; ZF = 1 ;
; ;
;\=============================================/;
.MODEL SMALL
.CODE
ORG 100h
TData : JMP Proses
Kal0 DB 'Tekan sembarang tombol untuk berhenti ! '
DB 13,10,'$'
Proses :
MOV AH,1 ; Servis untuk mengecek buffer keyboard
INT 16h ; Laksanakan !
JNZ EXIT ; Jika ada tombol yang ditekan, lompat
79
; Ke EXIT
MOV AH,09 ; Servis untuk cetak kalimat
LEA DX,Kal0 ; Ambil alamat efektif Kal0
INT 21h ; Cetak kalimat !
JMP Proses ; Lompat ke Proses
exit : INT 20h ; Kembali ke DOS !
END TData
Program 15.2. Membuat fungsi Keypressed
Bila program 15.2. dijalankan, maka pada layar akan ditampilkan tulisan:
Tekan sembarang tombol untuk berhenti !
Tulisan ini akan ditampilkan terus sampai anda menekan sembarang tombol.
15.5. MASUKAN KALIMAT DARI KEYBOARD
Pada program-program sebelumnya kita hanya bisa mendapatkan masukan satu karakter pada keybaord, bagaimana jika diinginkan masukan berupa suatu kalimat? Untuk itu DOS telah menyedikannya.
Interupsi 21h servis ke 0Ah, digunakan untuk mendapatkan masukan dari keyboard lebih dari satu karakter. Adapun aturan pemakainya adalah:
INPUT OUTPUT
AH = 0Ah Buffer yang berisi string
DS:DX= Buffer hasil masukan dari keyboard
Untuk menggunkan fungsi ini anda harus menyediakan sebuah buffer untuk menampung hasil masukan dari keyboard. Anda bisa membuat sebuah buffer seperti:
Buffer DB X,Y,Z DUP(?)
Pada byte pertama yang kita gambarkan sebagai "X", digunakan sebagai tanda dari banyaknya karakter yang dapat dimasukkan dari keyboard ditambah 1. Seperti bila anda memberikan nilai 23, maka karakter maksimum yang dapat dimasukkan adalah 22 karakter, karena satu karakter lagi digunakan khusus oleh tombol Enter(0Dh).
Pada byte kedua yang kita gambarkan sebagai "Y" ,digunakan oleh fungsi ini sebagai indikator banyaknya karakter yang telah diketikkan oleh user(Tombol Enter<0dh> tidak akan dihitung). Anda bisa memberikan tanda "?" untuk byte kedua ini, karena nilainya akan diisi secara otomatis nantinya.
Pada byte ketiga yang kita gambarkan sebagai "Z" inilah yang nantinya merupakan awal dari masukan string akan ditampung. Anda harus menyediakan banyaknya byte yang dibutuhkan, sesuai dengan byte pertama("X").
80
;/=========================================================\;
; Program : IN-KAL.ASM ;
; Author : S’to ;
; Fungsi : Input Kalimat dari ;
; keyboard. ;
;===========================================================;
; INTERUPSI 21h ;
;===========================================================;
; Input: ;
; AH = 0Ah ;
; DS:DX = Penampung dengan spesifikasi: ;
; Byte 1 = Maksimum karakter yang dapat dimasukkan ;
; Byte 2 = Akan dijadikan Indikator banyaknya ;
; karakter yang dimasukkan ;
; Byte 3 keatas = Tempat hasil masukan ditampung ;
; ;
; ;
;\=========================================================/;
.MODEL SMALL
.CODE
ORG 100h
TData : JMP Proses
T_Enter EQU 0Dh
Kal0 DB 'Ketikkan satu Kalimat : $'
Kal1 DB 13,10,'Kalimat pada buffer : $'
Buffer DB 23,?,23 DUP(?)
Proses : MOV AH,09
LEA DX,Kal0
INT 21h ; Cetak kalimat Kal0
MOV AH,0Ah ; Servis Input kalimat
LEA DX,Buffer ; DX menunjuk pada offset Buffer
INT 21h ; Input kalimat !
MOV AH,09
LEA DX,Kal1
INT 21h ; Cetak kalimat Kal1
LEA BX,Buffer+2 ; BX menunjuk byte ke 3 Buffer
Ulang:
CMP BYTE PTR [BX],T_Enter ; Apakah karakter Enter?
JE EXIT ; Ya! Lompat ke Exit
MOV DL,[BX] ; Masukkan karakter pada DL
MOV AH,02 ; Servis cetak karakter
INT 21h ; Cetak karakter
INC BX ; BX := BX+1
JMP Ulang ; Lompat ke Ulang
EXIT: INT 20h ; Kembali ke DOS !
END TData
Program 15.3. Masukan string dari Keyboard
Contoh dari hasil eksekusi program 15.3. setelah mendapat masukan dari keyboard:
Ketikkan satu Kalimat : Equasoft
81
Kalimat pada buffer : Equasoft
Adapun proses yang dilakukan pada program 15.3. adalah:
MOV AH,09
LEA DX,Kal0
INT 21h
Pertama-tama cetak kalimat Kal0 dengan servis 9 interupsi 21h, setelah itu:
MOV AH,0Ah
LEA DX,Buffer
INT 21h
Pada bagian inilah kita meminta masukan dari keyboard, dengan DX menunjuk pada buffer yang digunakan sebagai penampung.
MOV AH,09
LEA DX,Kal1
INT 21h
Setelah itu cetaklah kalimat pada Kal1
LEA BX,Buffer+2
Dengan perintah ini maka BX akan menunjuk pada byte ke 3, atau awal masukan string dari keyboard. Supaya lebih jelas, nilai pada buffer setelah mendapat masukan adalah:
Offset BX=Offset+2
_ _
+---+---+---+---+---+---+---+---+---+---+---+
| 9 | 8 | E | q | u | a | s | o | f | t | 0D|
+---+---+---+---+---+---+---+---+---+---+---+
Setelah BX mnunjuk pada karakter pertama hasil masukan, maka:
CMP BYTE PTR [BX],T_Enter
JE EXIT
Periksalah, apakah karakter yang ditunjukkan BX adalah 0D(Enter)? Bila ya, berarti akhir dari masukan. Perlu anda perhatikan disini, bahwa kita menggunakan BYTE PTR. Bila tidak digunakan, assembler akan bingung apakah kita ingin membandingkan isi alamat BX sebanyak 1 byte atau lebih dengan T_Enter.
MOV DL,[BX]
MOV AH,02
INT 21h
Bila bukan karakter enter, maka ambil karakter tersebut dan masukkan 82
pada register DL untuk dicetak.
INC BX
JMP Ulang
Tambahlah BX denga satu sehingga BX akan menunjuk pada karakter selanjutnya. Proses dilanjutkan sampai ketemu tanda 0D atau karakter Enter.
83
BAB XVI
PROCEDURE
Procedure merupakan suatu alat bantu yang sangat berguna. Dengan procedure suatu program yang besar bisa diselesaikan dengan lebih mudah. Proses pencarian kesalahanpun akan lebih mudah bila digunakan procedure.
16.1. MEMBUAT PROCEDURE
Untuk membuat procedure bisa anda gunakan bentuk seperti pada gambar 16.1.
-------------------------------------------------------------
NamaP PROC NEAR/FAR
+---------+
| Program |
+---------+
RET
NamaP ENDP
-------------------------------------------------------------
Gambar 16.1. Model Procedure
"NamaP" adalah nama dari procedure yang kita definisikan sendiri. Untuk memudahkan nama untuk procedure bisa anda definisikan sesuai dengan fungsi dari procedure tersebut, seperti CLS untuk procedure yang tugasnya menghapus layar.
Dibelakang kata "PROC" anda harus memilih bentuk dari procedure tersebut, yaitu "NEAR" atau "FAR". Bentuk "NEAR" digunakan jika procedure tersebut nantinya dipanggil oleh program yang letaknya masih satu segment dari procedure tersebut. Pada program COM yang terdiri atas satu segment, kita akan selalu menggunakan bentuk "NEAR". Sebaliknya bentuk "FAR" ini digunakan bila procedure dapat dipanggil dari segment lain. Bentuk ini akan kita gunakan pada program EXE.
Perintah "RET(Return)" digunakan untuk mengembalikan Kontrol program pada sipemanggil procedure. Pada bentuk NEAR perintah RET ini akan memPOP atau mengambil register IP dari stack sebagai alamat loncatan menuju program pemanggil procedure. Sedangkan pada bentuk "FAR" perintah RET akan mengambil 84
register IP dan CS dari stack sebagai alamat loncatan menuju program pemanggil procedure. Alamat kembali untuk procedure disimpan pada stack pada saat procedure tersebut dipanggil dengan perintah "CALL", dengan syntax:
CALL NamaP
Perintah Call ini akan menyimpan register IP saja bila procedure yang dipanggil berbentuk "NEAR". Bila procedure yang dipanggil berbentuk "FAR", maka perintah "CALL" akan menyimpan register CS dan IP.
16.2. MENGGUNAKAN PROCEDURE
Sebagai contoh dari pemakaian procedure akan kita lihat pada program 16.1 yang mencetak karakter dengan procedure.
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~;
; PROGRAM : PROC_KAR.ASM ;
; FUNGSI : MENCETAK KARATER ;
; DENGAN PROCEDURE ;
; ;
;==========================S’to=;
.MODEL SMALL
.CODE
ORG 100h
Proses : CALL Cetak_Kar ; Panggil Cetak_Kar
INT 20h
Cetak_Kar PROC NEAR
MOV AH,02h
MOV DL,'S'
INT 21h ; Cetak karakter
RET ; Kembali kepada si pemanggil
Cetak_Kar ENDP ; END Procedures
END Proses
Program 16.1 Menggunakan Procedure
Bila program 16.1. dijalankan, maka pada layar akan ditampilkan huruf "S". Untuk membuat sebuah procedure ingatlah untuk menyimpan semua register yang digunakan oleh procedure tersebut dan mengembalikan semua isi register pada akhir procedure. Hal ini dilakukan untuk menjaga supaya program utama yang menggunakan procedure tersebut tidak menjadi kacau nantinya. Sebagai contohnya bisa anda lihat pada program 16.2.
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~;
; PROGRAM : PROC_KA1.ASM ;
; FUNGSI : MENCETAK KARATER ;
85
; DENGAN PROCEDURE ;
; ;
;==========================S’to=;
.MODEL SMALL
.CODE
ORG 100h
TData : JMP Proses
Kar DB ?
Klm DB 'BATMAN SI MANUSIA KELELAWAR ' ; 28 Karakter
Proses : MOV CX,28 ; Banyaknya pengulangan
XOR BX,BX ; Addressing Mode
Ulang :
MOV DL,Klm[BX]
MOV Kar,DL
CALL Cetak_Kar ; Panggil Cetak_Kar
INC BX
LOOP Ulang
INT 20h
Cetak_Kar PROC NEAR
PUSH AX ; Simpan semua register
PUSH DX ; Yang digunakan
MOV AH,02h
MOV DL,Kar
INT 21h ; Cetak karakter
POP DX ; Kembalikan semua register
POP AX ; Yang disimpan
RET ; Kembali kepada si pemanggil
Cetak_Kar ENDP ; END Procedures
END TData
Program 16.2. Menggunakan Procedure
Bila program 16.2. dijalankan, maka pada layar akan ditampilkan:
BATMAN SI MANUSIA KELELAWAR
Pada procedure kita tidak bisa menggunakan parameter, inilah salah satu kelemahan dari procedure yang sangat berarti. Untuk menggunakan parameter anda harus menggunakan MACROS.
86
BAB XVII
MACRO
Macro hampir sama dengan procedure, yang dapat membantu anda dalam membuat program yang besar. Dengan Macro anda tidak perlu menggunakan perintah "CALL" dan anda juga bisa menggunakan parameter dengan mudah. Suatu ciri dari pemrograman bahasa tingkat tinggi!
17.1. MEMBUAT MACRO
Macro adalah lebih mudah dibuat daripada procedure. Untuk membuat Macro bisa anda gunakan bentuk seperti pada gambar 17.1.
---------------------------------------------------------------
NamaM MACRO [P1,P2,,]
+------------+
| Program |
+------------+
ENDM
---------------------------------------------------------------
Gambar 17.1. Model Macro
"P1" dan "P2" adalah parameter yang bisa anda gunakan pada macro. Parameter ini berbentuk optional, artinya bisa digunakan ataupun tidak. Supaya lebih jelas bisa anda lihat pada program MAC1 yang menggunakan macro ini untuk mencetak karakter.
Cetak_Kar MACRO Kar
MOV CX,3
MOV AH,02
MOV DL,Kar
Ulang :
INT 21h ; Cetak Karakter
LOOP Ulang
ENDM ; End Macro
;-----------------------------------;
; Program : MAC1.ASM ;
; Fungsi : Menggunakan Macro ;
; Untuk mencetak ;
; huruf 'SSS' ;
;-----------------------------------;
.MODEL SMALL
.CODE
ORG 100h
Proses:
Cetak_Kar 'S' ; Cetak Huruf S
INT 20h
END Proses
Program 17.1. Menggunakan Macro
87
Dari program MAC1 bisa anda lihat betapa mudahnya untuk menggunakan macro. Pada procedure, setiap kali kita memanggilnya dengan perintah CALL maka program akan melompat pada procedure tersebut, sehingga setiap procedure hanya terdapat satu kali saja pada program. Lain halnya dengan Macro, setiap terjadi pemanggilan terhadap macro atau dapat dikatakan secara kasar, setiap kita memanggil macro dengan menuliskan nama macronya dalam program, maka seluruh isi macro akan dipindahkan pada program yang memanggilnya. Dengan demikian bila pada program anda memanggil suatu macro sebanyak 10 kali maka macro tersebut akan disisipkan 10 kali pada program. Hal inilah yang menyebabkan program yang menggunakan macro ukuran programnya menjadi lebih besar. Tetapi hal ini juga yang menyebabkan program yang menggunakan macro lebih cepat daripada procedure, karena pada procedure komputer harus melakukan lompatan tetapi pada macro tidak perlu.
17.2. LABEL PADA MACRO
Pada macro anda bisa menggunakan label seperti biasa. Tetapi anda harus ingat, karena setiap pemanggilan Macro akan menyebabkan seluruh isi macro tersebut disisipkan pada program, maka pada macro yang didalamnya menggunakan label hanya dapat dipanggil sebanyak satu kali. Bila anda menggunakanya lebih dari satu kali maka akan terjadi "**Error** Symbol already defined elsewhere: ULANG" karena dianggap kita menggunakan label yang sama.
Untuk menghindari hal itu, gunakanlah directif LOCAL. Dengan directif LOCAL assembler akan membedakan label tersebut setiap kali terjadi pemanggilan terhadapnya.
Cetak_Kar MACRO Kar
LOCAL Ulang ; Label 'Ulang' jadikan Local
MOV CX,3
MOV AH,02
MOV DL,Kar
Ulang:
INT 21h ; Cetak Karakter
LOOP Ulang
ENDM ; End Macro
;-----------------------------------;
; Program : MAC2.ASM ;
; Fungsi : Menggunakan Macro ;
; Untuk mencetak ;
; huruf 'PPPCCC' ;
;-----------------------------------;
.MODEL SMALL
.CODE
ORG 100h
Proses:
Cetak_Kar 'P' ; Cetak Huruf P
Cetak_Kar 'C' ; Cetak Huruf C
INT 20h
END Proses
88
Program 17.2. Menggunakan Perintah LOCAL
17.3. PUSTAKA MACRO
Bila kita sering menggunakan suatu fungsi seperti mencetak kalimat pada setiap program yang kita buat, tentu saja akan sangat membosankan karena setiap kali kita harus membuat fungsi yang sama. Dengan macro anda bisa menghindari hal tersebut dengan membuat suatu pustaka macro. Pustaka tersebut bisa anda simpan dengan suatu nama, misalnya 'pustaka.mcr'. File yang tersimpan adalah dalam bentuk ASCII, tanpa perlu di compile.
;/========================\;
; Program : PUSTAKA.MCR ;
;\========================/;
Cetak_Kar MACRO Kar ; Macro untuk mencetak
MOV AH,02 ; Karakter
MOV DL,Kar
INT 21h
ENDM
Cetak_Klm MACRO Klm ; Macro untuk mencetak
LEA DX,Klm ; kalimat
MOV AH,09
INT 21h
ENDM
Program 17.3. Pustaka.MCR
Setelah program 17.3. anda ketikkan, simpanlah dengan nama 'PUSTAKA.MCR'. Anda bisa menggunakan macro pada file pustaka.mcr dengan hanya manambahkan kata:
INCLUDE PUSTAKA.MCR
Sebagai contohnya bisa anda lihat pada program 17.4. yang menggunakan file pustaka.mcr ini untuk mencetak kalimat dan karakter.
;/====================================\;
; Program : TPTK.ASM ;
; Fungsi : Contoh menggunakan ;
; pustaka macro ;
;\====================================/;
INCLUDE PUSTAKA.MCR ; Gunakan file PUSTAKA.MCR
.MODEL SMALL
.CODE
ORG 100h
TData : JMP Proses
Kal0 DB 'PENGGUNAAN PUSTAKA MACRO $'
Proses:
Cetak_Klm Kal0 ; Cetak Kalimat Kal0
Cetak_Kar 'Y' ; Cetak Huruf 'Y'
89
INT 20h
END TData
Program 17.4. Menggunakan Pustaka.MCR
Setelah program 17.4. anda jalankan, maka pada layar akan ditampilkan:
PENGGUNAAN PUSTAKA MACRO Y
17.4. MACRO ATAU PROCEDURE ?
Banyak pro dan kontra mengenai macro dan procedure ini. Sebagian orang menganggap macro akan merugikan program, tetapi banyak juga yang menganggap macro adalah pemecahan yang tepat dalam pemrograman assembler yang terkenal sulit untuk digunakan. Kini apa yang akan anda pakai ? Macro ataukah procedure ? Untuk itu marilah kita lihat dahulu perbedaan antara procedure dan macro ini.
- Procedure tidak memperpanjang program, karena hanya muncul sekali saja pada program.
- Macro akan muncul pada program setiap terjadi pemanggilan terhadap macro, sehingga macro akan memperpanjang program.
- Untuk menggunakan procedure anda harus memanggilnya dengan perintah CALL dan dalam procedure diakhiri dengan RET.
- Macro bisa anda gunakan dengan memanggil langsung namanya dan pada macro tidak perlu diakhiri dengan RET.
- Procedure akan memperlambat program, karena setiap pemanggilan terhadap procedure, komputer harus melakukan lompatan.
- Macro tidak memperlambat program karena komputer tidak perlu melakukan lompatan.
- Pada procedure anda tidak bisa menggunakan parameter secara langsung. Bila anda ingin menggunakan parameter bisa dengan melalui stack atau register.
- Macro dengan mudah bisa menggunakan parameter, suatu ciri bahasa tingkat tinggi.
- Macro lebih mudah dibuat dan digunakan daripada procedure.
Setelah melihat perbedaan-perbedaan tersebut, kapankah kita menggunakan procedure dan kapankah menggunakan macro ?
- Jika fungsi tersebut jarang dipanggil, gunakanlah MACRO karena macro tidak
memperlambat proses.
90
- Jika fungsi tersebut sering dipanggil, gunakanlah PROCEDURE karena
procedure tidak memperbesar program.
- Jika fungsi tersebut kecil, gunakanlah MACRO. Karena pengaruh terhadap
besarnya program hanya sedikit dan program akan lebih cepat.
- Jika fungsi tersebut besar, gunakanlah PROCEDURE. Karena procedure tidak
memperbesar program.
91
BAB XVIII
OPERASI PADA LAYAR
Layar dapat dikatakan merupakan media yang menarik untuk dibahas, karena pada layar ini tampilan program bisa dijadikan semenarik mungkin. Pada bagian ini yang paling penting dan harus anda kuasai adalah bagian yang menerangkan mengenai memory layar yang digunakan sebagai data ditampilkan gambar/teks dilayar.
18.1. MEMORY LAYAR
Pada layar disediakan suatu buffer atau memory yang mencatat tentang apa yang akan ditampilkan dilayar. Komputer akan membaca data pada memory layar untuk memperbaharui tampilan pada layar yang dilakukan kurang lebih 70 kali setiap detiknya. Cepatnya penulisan kembali gambar pada layar ini dinamakan sebagai "refresh rate".
Pada layar monitor monokrom(tidak berwarna), alamat memory yang digunakan sebagai buffer digunakan lokasi memory dimulai pada alamat B000h:0000. Pada monitor berwarna digunakan lokasi memory mulai alamat B800h:0000. Untuk pembahasaan kita selanjutnya akan selalu digunakan alamat buffer layar berwarna(B800h).
18.2. TAMPILAN TEKS PADA LAYAR
Pada modus teks, setiap saat komputer akan selalu melihat pada alamat B800h:0000 sebanyak satu byte untuk menampilkan karakter ASCII pada posisi kolom 0 dan baris 0. Kemudian alamat B800h:0001 digunakan sebagai atribut dari posisi kolom 0 dan baris 0. Alamat B800h:0002 digunakan sebagai data untuk menampilkan karakter ASCII pada posisi kolom 1 dan baris 0. Dan alamat B800h:0003 digunakan sebagai data untuk menampilkan atribut dari posisi kolom 1 baris 0. Demikian seterusnya memory layar digunakan(Lihat gambar 18.1).
<<<>>>
Gambar 18.1. Penggunaan Memory Layar Untuk
Menampilkan Teks Dan Atributnya
Dari sini sudah dapat kita ketahui bahwa sebuah karakter pada saat ditampilkan dimonitor menggunakan 2 byte, dimana byte pertama digunakan untuk kode ASCII-nya dan byte berikutnya digunakan untuk atribut dari karakter tersebut.
Karena pada mode default, layar teks dibagi menjadi 80 kolom dan 25 92
baris(80*25), maka memory yang dibutuhkan untuk satu layar adalah:
80 * 25 * 2 = 4000 Byte
Dengan alamat memory yang digunakan secara berurutan ini, dimana teks akan menempati offset genap dan atribut menempati offset ganjil, alamat dari posisi karakter maupun atribut bisa dihitung dengan menggunakan rumus:
Offset Karakter = (Baris * 160) + (Kolom * 2)
Offset Atribut = (Baris * 160) + (Kolom * 2)+1
Dengan demikian bila kita ingin menampilkan karakter 'S' pada posisi kolom 40 dan baris 12 maka alamat yang digunakan adalah: (12*160)+(40*2)=2000, atau tepatnya B800h:2000. Untuk menampilkan atribut pada posisi kolom 40 dan baris 12 maka alamat yang digunakan adalah:(12*160)+(40*2)+1=2001, atau tepatnya B800h:2001. Sebagai contohnya bisa anda lihat pada program 18.1. yang akan menampilkan karakter "S" pada posisi kolom 40 dan baris 12 dengan atributnya 95.
Tulis_Kar MACRO X,Y,Kar,Attr
MOV AX,0B800h
MOV ES,AX ; ES Menunjuk pada segment layar
MOV AH,Y
MOV AL,160
MUL AH ; Hitung offset baris
MOV BX,AX ; Simpan hasilnya pada BX
MOV AH,X
MOV AL,2
MUL AH ; Hitung offset kolom
ADD BX,AX ; Tambahkan hasilnya pada BX
MOV AL,Kar ; AL=karakter yang akan ditampilkan
MOV AH,Attr ; AH=Atribut yang akan ditampilkan
MOV ES:[BX],AL ; Tampilkan Karakter dan atributnya
MOV ES:[BX+1],AH ; pada posisi kolom X dan baris Y
ENDM
;/===============================================\;
; Program : LAYAR1.ASM ;
; Author : S’to ;
; ;
; Fungsi : Menampilkan karakter dan atributnya ;
; dengan menuliskannya langsung pada ;
; memory layar ;
;\===============================================/;
.MODEL SMALL
.CODE
ORG 100h
Proses :
Tulis_Kar 40 12 'S' 95 ; Tulis karakter 'S' dengan
; no atribut 95 pada posisi
INT 20h ; kolom 40 dan baris 12
END Proses
Program 18.1. Menuliskan langsung pada memory layar 93
Dengan mengertinya anda pada program 18.1. ini maka banyak program menarik yang dapat anda hasilkan, seperti program rontok, menu sorot, shadow dan lain sebagainya.
18.2.1 MEMBUAT PROGRAM RONTOK
Pada bagian ini akan kita lihat, bagaimana caranya menggeser tulisan dengan mengakses memory layar secara langsung dengan program rontok.
Program rontok adalah program yang akan membersihkan layar dengan cara menjatuhkan atau merontokkan huruf pada layar satu persatu.
Delay MACRO
PUSH CX ; Macro ini digunakan untuk
XOR CX,CX ; menunda program, dan
Loop1:
LOOP Loop1 ; hanya melakukan looping
POP CX
ENDM
Geser MACRO PosY
PUSH AX
PUSH BX
PUSH CX ; Simpan semua register yang digunakan
XOR CX,CX
MOV AL,26
SUB AL,PosY
MOV CL,AL ; CX=banyaknya pergeseran kebawah
Loop2:
MOV AL,BYTE PTR ES:[BX] ; AL=Karakter pada layar
MOV BYTE PTR ES:[BX+160],AL ; Geser ke bawah
Hilang:
MOV BYTE PTR ES:[BX],' ' ; Hapus karakter
; sebelumnya
Delay ; delay, supaya bisa
; terlihat
ADD BX,160 ; Menuju baris selanjutnya
LOOP Loop2 ; Ulangi ke Loop2
POP CX
POP BX
POP AX ; Kembalikan semua register yang digunakan
ENDM
;/===================================================\;
; Program : RONTOK.ASM ;
; Author : S’to ;
; Fungsi : Membersihkan layar dengan cara ;
; merontokkan hurufnya satu persatu;
; ;
;\====================================================/
94
.MODEL SMALL
.CODE
ORG 100h
TData : JMP Proses
PosY DB ?
Proses:
MOV AX,0B800h
MOV ES,AX ; ES mencatat segment layar
MOV BX,3998 ; Posisi karakter 80,25
MOV CX,25 ; Banyaknya pengulangan baris
UlangY :
MOV PosY,CL ; PosY mencatat posisi baris
PUSH CX ; CX mencatat posisi Y
MOV CX,80 ; Banyaknya pengulangan Kolom
UlangX :
CMP BYTE PTR ES:[BX],33 ; Apakah ada karakter
; pada layar ?
JB Tdk ; Lompat ke Tdk, jika tidak ada
Geser PosY ; Geser karakter tersebut ke bawah
Tdk :
SUB BX,2 ; BX menunjuk karakter selanjutnya
LOOP UlangX ; Proses 80 kali untuk kolom
POP CX ; Ambil posisi Y
LOOP UlangY ; Ulangi dan ganti baris ke atas
EXIT:
INT 20h
END TData
Program 18.2. Merontokkan huruf pada layar
Bila program 18.2 dijalankan, maka semua huruf pada layar akan dirontokkan satu persatu sampai habis.
<<<>>>
Gambar 18.2. Hasil eksekusi program 18.2.
Adapun penjelasan programnya adalah:
Delay MACRO
PUSH CX
XOR CX,CX
Loop1:
LOOP Loop1
POP CX
ENDM
Macro ini digunakan untuk menunda program. Dengan menolkan CX, maka looping yang akan didapatkan menjadi FFFFh kali, karena pengurangan 0 dengan 1 akan akan menghasilkan nilai -1 atau FFFFh.
95
Geser MACRO PosY
PUSH AX
PUSH BX
PUSH CX
Pada macro inilah nantinya huruf-huruf pada layar akan digeser. Untuk itu simpanlah semua register yang digunakan oleh macro ini karena pada program utama, register-register juga digunakan.
XOR CX,CX
MOV AL,26
SUB AL,PosY
MOV CL,AL
Ini adalah bagian dari macro geser yang akan menghitung banyaknya pergeseran kebawah yang akan dilakukan, dengan melihat posisi dari huruf yang digeser pada variabel "PosY".
Loop2:
MOV AL,BYTE PTR ES:[BX]
MOV BYTE PTR ES:[BX+160],AL
Hilang:
MOV BYTE PTR ES:[BX],' '
Delay
ADD BX,160
LOOP Loop2
Bagian inilah yang akan menggeser tulisan pada layar. Register BX ditambah dengan 160 untuk mengakses baris dibawahnya.
POP CX
POP BX
POP AX
ENDM
Pada akhir macro, kembalikanlah semua register yang telah disimpan pada awal macro. Ingat urutannya harus terbalik. Pada program utama:
.MODEL SMALL
.CODE
96
ORG 100h
TData : JMP Proses
PosY DB ?
Pertama-tama siapkanlah sebuah variabel untuk menampung posisi dari baris yang sedang diakses.
Proses:
MOV AX,0B800h
MOV ES,AX
MOV BX,3998
MOV CX,25
Register ES, kita gunakan sebagai penunjuk segment layar, yaitu pada segment B800h. Register BX yang nantinya akan kita gunakan sebagai penunjuk offset dari ES diberi nilai 3998. Dengan demikian pasangan ES:BP akan menunjuk pada karakter dipojok kanan bawah atau posisi 79,24.
UlangY :
MOV PosY,CL
PUSH CX
MOV CX,80
UlangX :
CMP BYTE PTR ES:[BX],33
JB Tdk
Geser PosY
Tdk :
SUB BX,2
LOOP UlangX
POP CX
LOOP UlangY
EXIT:
INT 20h
END TData
Kemudian lakukanlah proses dengan melihat apakah ada karakter atau tidak. Hal ini dapat dilakukan dengan membandingkannya dengan kode ASCII 33, bila data pada buffer layar dibawah ASCII 33 artinya tidak ada karakter pada 97
layar.
Jika ada karakter pada layar maka proses geser dilakukan, sebaliknya jika tidak ada karakter proses akan menuju pada posisi selanjutnya dan melakukan hal yang sama.
18.3. MENGGULUNG LAYAR KEATAS ATAU KEBAWAH
BIOS menyediakan suatu fungsi yang dapat digunakan untuk mengulung layar dengan batasan yang kita tentukan. Adapun aturan pemakaian dari interupsi ini adalah:
INPUT:
AH = Diisi dengan 6 untuk menggulung layar keatas, untuk
menggulung layar kebawah diisi dengan 7.
AL = Banyaknya pergeseran yang akan dilakukan. Jika diisi dengan
nol, maka seluruh isi window akan dihapus.
CH = Posisi baris kiri atas window
CL = Posisi kolom kiri atas window
DH = Posisi baris kanan bawah window
DL = Posisi kolom kanan bawah window
BH = Atribut yang akan mengisi hasil penggulungan window
Setelah semuanya anda persiapkan laksanakanlah interupsi 10h. Anda bisa membersihkan layar dengan fungsi ini dengan meletakkan 0 pada register AL, dan membuat window pada posisi 0,0 dan 79,24.
DELAY MACRO ; Macro untuk menunda program
LOCAL Ulang
PUSH CX
XOR CX,CX
Ulang:
LOOP Ulang
POP CX
ENDM
Scrool MACRO X1,Y1,X2,Y2,Arah
PUSH CX
MOV AH,Arah ; Servis Gulung keatas atau kebawah
MOV AL,1 ; Jumlah Baris
MOV CL,X1 ; Kolom kiri atas
MOV CH,Y1 ; Baris kiri Atas
MOV DL,X2 ; Kolom kanan bawah
MOV DH,Y2 ; Baris kanan bawah
MOV BH,01000111b ; Atribut hasil penggulungan
INT 10h
POP CX
ENDM
;/===============================================\;
; Program : SCROOL.ASM ;
; Author : S’to ;
; Fungsi : Menggulung layar ;
98
;\===============================================/;
.MODEL SMALL
.CODE
ORG 100h
TData : JMP Proses
G_Atas EQU 6 ; Servis untuk menggulung ke atas
G_Bawah EQU 7 ; Servis untuk menggulung ke bawah
Proses:
MOV CX,7
Ulang:
Scrool 20 7 60 14 G_Bawah
delay
LOOP Ulang
INT 20h
END TData
Program 18.3. Mengulung layar
Bila program 18.3. anda jalankan, maka pada layar akan tampak seperti gambar 18.2.
<<<>>>
Gambar 18.3. Hasil eksekusi program 18.3.
18.4. MEMINDAHKAN POSISI KURSOR
Untuk memindahkan posisi kursor, sama halnya dengan perintah GOTOXY pada pascal, bisa anda gunakan interupsi dari BIOS. Interupsi yang digunakan adalah interupsi 10h dengan aturan pemakaian:
INPUT:
AH = 2
DH = Posisi Baris(00-24)
DL = Posisi Kolom(00-79)
BH = Halaman layar(0=default)
Adapun contoh dari pemakaian fungsi ini dalam bentuk macro adalah:
GOTOXY MACRO X,Y
MOV AH,02
XOR BX,BX
MOV DH,Y
MOV DL,X
INT 10h
99
ENDM
18.5. MENCARI POSISI KURSOR
Sama halnya dengan fungsi WhereX dan WhereY dalam pascal, didalam assembler anda juga bisa mengetahui posisi dari kursor. Untuk itu telah tersedia interupsi 10h dari BIOS dengan aturan pemakaian:
INPUT: OUTPUT:
AH = 03 DH = Posisi Baris
BH = Halaman Layar(0=default) DL = Posisi Kolom
Adapun contoh pemakaian fungsi ini dalam bentuk macro bisa anda lihat sebagai berikut:
WherePos MACRO X,Y
MOV AH,03
MOV BH,0
MOV X,DL
MOV Y,DH
ENDM
18.6. MEMBUAT MENU SOROT
Dewasa ini, menu-menu yang disajikan oleh program yang besar hampir semuanya dalam bentuk menu sorot. Kini dengan sedikit pengetahuan mengenai memory layar akan kita buat suatu menu sorot yang sederhana. Menu ini bisa dikembangkan atau digunakan untuk program yang anda buat.
Cls MACRO ; Macro untuk menghapus layar
MOV AX,0600h
XOR CX,CX
MOV DX,184Fh
MOV BH,10 ; Atribut Hijau diatas hitam
INT 10h
ENDM
GotoXY MACRO X,Y ; Macro untuk memindahkan kursor
MOV AH,02
XOR BX,BX
MOV DH,Y
MOV DL,X
INT 10h
ENDM
SimpanL MACRO ; Macro untuk menyimpan seluruh
LOCAL Ulang ; isi layar monitor
MOV AX,0B800h
MOV ES,AX
MOV CX,4000
XOR BX,BX
Ulang:
MOV AL,ES:[BX]
100
MOV Layar[BX],AL
INC BX
LOOP Ulang
ENDM
BalikL MACRO ; Macro untuk mengembalikan semua
LOCAL Ulang ; isi layar yang telah disimpan
MOV CX,4000
XOR BX,BX
Ulang:
MOV AL,Layar[BX]
MOV ES:[BX],AL
INC BX
LOOP Ulang
ENDM
Sorot MACRO X,Y ; Macro untuk membuat sorotan
LOCAL Ulang ; pada menu
MOV BL,Y
MOV AL,160
MUL BL
MOV BX,AX
MOV AL,X
MOV AH,2
MUL AH
ADD BX,AX
INC BX ; Alamat warna pada posisi X,Y
MOV CX,25 ; Panjangnya sorotan
Ulang:
MOV BYTE PTR ES:[BX],4Fh ; Atribut sorotan
; putih diatas merah
ADD BX,2
LOOP Ulang
ENDM
Readkey MACRO ; Macro untuk membaca masukan dari
MOV AH,00 ; keyboard.
INT 16h ; hasilnya AH=Extended, AL=ASCII
ENDM
MenuL MACRO String ; Macro untuk mencetak menu
MOV AH,09
LEA DX,String
INT 21h
ENDM
;/==============================================\;
; Program : SOROT.ASM ;
; Author : S’to ;
; Fungsi : Membuat menu sorot untuk ;
; digunakan program ;
;\==============================================/;
.MODEL SMALL
.CODE
ORG 100h
TData: JMP Proses
Layar DB 4000 DUP (?)
Menu DB 9,9,'+=============================+',13,10
DB 9,9,'| »»» MENU SOROT ««« |',13,10
DB 9,9,'+=============================+',13,10
DB 9,9,'| |',13,10
DB 9,9,'| 1. Pilihan pertama |',13,10
101
DB 9,9,'| 2. Pilihan Kedua |',13,10
DB 9,9,'| 3. Pilihan Ketiga |',13,10
DB 9,9,'| 4. Pilihan Keempat |',13,10
DB 9,9,'| |',13,10
DB 9,9,'+=============================+$'
PosX DB 22 ; Posisi kolom mula-mula
PosY DB 12 ; Posisi baris mula-mula
Panah_Atas EQU 72 ; Kode tombol panah atas
Panah_Bawah EQU 80 ; Kode tombolpanah bawah
TEnter EQU 0Dh ; Kode tombol Enter
Proses :
Cls ; Hapus layar
GotoXY 0 8 ; kursor = 0,8
MenuL Menu ; Gambar menu
SimpanL ; Simpan isi layar
Ulang :
BalikL ; Tampilkan isi layar yang
; disimpan
Sorot PosX,PosY ; Sorot posisi X,Y
Masukan:
Readkey ; Baca masukan dari keyboard
CMP AH,Panah_Bawah ; Panah bawah yang ditekan ?
JE Bawah ; Ya! lompat bawah
CMP AH,Panah_Atas ; Panah atas yang ditekan ?
JE CekY ; Ya, lompat CekY
CMP AL,TEnter ; Tombol enter yang ditekan ?
JNE Masukan ; Bukan, lompat ke ulangi
JMP Selesai ; Ya, lompat ke selesai
CekY :
CMP PosY,12 ; Apakah sorotan paling atas ?
JE MaxY ; Ya! lompat ke MaxY
DEC PosY ; Sorotkan ke atas
JMP Ulang ; Lompat ke ulang
MaxY :
MOV PosY,15 ; PosY=Sorotan paling bawah
JMP Ulang ; lompat ke ulang
Bawah :
CMP PosY,15 ; apakah sorotan paling bawah ?
JE NolY ; Ya! lompat ke NolY
INC PosY ; Sorotkan ke bawah
JMP Ulang ; Lompat ke ulang
NolY :
MOV PosY,12 ; Sorotan paling atas
JMP Ulang ; Lompat ke ulang
Selesai:
INT 20h
END TData
Program 18.4. Membuat Menu Sorot
Bila program 18.4. dijalankan, maka anda akan mendapatkan suatu menu sorot yang menarik, seperti pada gambar 18.4.
<<<>>>
Gambar 18.4. Hasil eksekusi program 18.4.
102
sorot yang menarik, seperti pada gambar 18.4.
<<<>>>
Gambar 18.4. Hasil eksekusi program 18.4.
102
18.7. HALAMAN LAYAR
Telah kita bahas bahwa pada normalnya satu layar akan menggunakan 4000 byte memory. Tetapi memory yang disediakan untuk layar ini sebenarnya malah beberapa kali lipat lebih banyak dari 4000 byte, karenanya terciptalah apa yang dinamakan 'paging' atau halaman tampilan layar.
Banyaknya halaman tampilan ini sangat bervariasi karena tergantung jumlah memory yang tersedia dan jumlah memory yang digunakan oleh satu halaman tampilan. Untuk alamat awal dari masing-masing halaman tampilan bisa anda lihat pada gambar 18.5.
+----------+--------------+
| Halaman | 80 X 25 |
+----------+--------------+
| 0 | B800:0000h |
| 1 | B800:1000h |
| 2 | B800:2000h |
| 3 | B800:3000h |
| 4 | B800:4000h* |
| 5 | B800:5000h* |
| 6 | B800:6000h* |
| 7 | B800:7000h* |
+----------+--------------+
Ket : * tidak berlaku pada CGA
Gambar 18.5. Alamat Awal Halaman Tampilan
Untuk mengakses memory halaman tampilan yang lain pada modus teks, rumus yang telah kita buat terdahulu bisa anda perbaharui menjadi:
Offset Karakter= (Baris * 160)+(Kolom * 2) + (Halaman*1000h)
Offset Atribut = (Baris * 160)+(Kolom * 2)+1+(Halaman*1000h)
18.8. MERUBAH HALAMAN TAMPILAN
Secara default halaman tampilan yang digunakan adalah halaman tampilan ke 0, yang beralamat awal pada B800:0000h. Untuk merubah halaman tampilan yang aktif ini bisa anda gunakan servis 5 dari interupsi 10h. Adapun aturan pemakaian servis ini adalah:
INPUT:
AH = 5
103
AL = Nomor halaman tampilan yang akan diaktifkan
Delay MACRO Rep ; Macro ini untuk menunda program
LOCAL Ulang
PUSH CX
MOV DX,Rep
SUB CX,CX
Ulang:
LOOP Ulang
DEC DX
CMP DX,0
JNZ Ulang
POP CX
ENDM
Ak_Page MACRO No ; Macro ini digunakan untuk
MOV AH,5 ; mengaktifkan halaman layar
MOV AL,No
INT 10h
ENDM
;/=============================================\;
; Program : PAGE.ASM ;
; Author : S’to ;
; Fungsi : Untuk mengaktifkan halaman;
; layar tertentu ;
;\=============================================/;
.MODEL SMALL
.CODE
ORG 100h
TData : JMP Proses
Kal0 DB 'INI ADALAH HALAMAN TAMPILAN KE 2 ',13,10
DB ' DENGAN ALAMAT AWAL B800:1000h !!! $'
Proses:
Ak_Page 2 ; Aktifkan halaman layar yang ke 2
MOV AH,09 ;
LEA DX,Kal0 ; Tulis kalimat pada halaman ke 2
INT 21h ;
MOV CX,3 ; Banyaknya pengulangan
Ulang:
Ak_Page 2 ; Aktifkan halaman ke 2
Delay 100
Ak_Page 0 ; Aktifkan halaman ke 0
Delay 100
LOOP Ulang
INT 20h
END Tdata
Program 18.5. Halaman Layar
Bila program 18.5. anda jalankan, maka dapat anda lihat perpindahan halaman aktif dari halaman tampilan 0 (default DOS) dan halaman tampilan 2.
Catatan:
Bila anda melakukan CLS dengan DOS, maka hanya halaman tampilan aktif yang akan terhapus, sedangkan data pada halaman tampilan yang lain akan tetap.
104
18.9. MERUBAH BENTUK KARAKTER
Pada modus teks, karakter-karakter tersusun atas titik-titik yang disebut sebagai pixel. Pixel-pixel yang membentuk karakter- karakter ini disimpan dalam tabel. pada EGA terdapat 4 buah tabel, sedangkan pada VGA terdapat 8 buah tabel karakter(Masing- masing 8 KB).
Karakter-karakter yang ditampilkan pada layar monitor diambil dari tabel-tabel yang membentuk karakter ini. Secara default tabel yang akan digunakan adalah tabel ke nol(0).
Bila monitor anda adalah monitor EGA keatas, maka bentuk karakter bisa diubah dengan mengubah isi dari tabel yang menyusun karakter-karakter ini. Untuk itu BIOS telah menyediakan interupsi 10h, service 11h, subservis 00 untuk keperluan ini. Adapun aturan dari pemakaiannya adalah:
INPUT:
AH = 11h
AL = 00h
CX = Jumlah bentuk karakter yang akan diganti
DX = Kode ASCII karakter awal yang akan diganti
BL = Nomor tabel karakter yang diubah
BH = Jumlah byte perkarakter
ES:BP = Alamat buffer pola karakter
;/=====================================================\;
; Program : MAP.ASM ;
; Author : S’to ;
; Fungsi : Untuk merubah bentuk karakter ;
; yang biasa digunakan. ;
; Huruf 'A', akan diubah bentuknya ;
; menjadi berbentuk pedang ! ;
;\=====================================================/;
.MODEL SMALL
.CODE
ORG 100h
TData : JMP Proses
Tabel DB 00011000b ; __
DB 00011000b ; __
DB 10011001b ; _ __ _
DB 11111111b ; ________
DB 10011001b ; _ __ _
DB 00011000b ; __
DB 00011000b ; __
DB 00011000b ; __
DB 00011000b ; __
DB 00011000b ; __
DB 00011000b ; __
DB 00011000b ; __
DB 00011000b ; __
DB 00011000b ; __
DB 00011000b ; __
DB 00001000b ; _
Proses :
MOV AX,1100h ; Servis
MOV DX,'A' ; Karakter ASCII awal yang akan diganti
MOV CX,1 ; Banyaknya karakter yang akan diganti
MOV BL,0 ; Nomor blok pemuatan karakter
105
MOV BH,16 ; Jumlah byte perkarakter
LEA BP,Tabel ; Lokasi tabel
INT 10h
INT 20h
END TData
Program 18.6. Merubah bentuk karakter
Bila program 18.6. dijalankan, maka semua karakter "A" akan akan segera berubah bentuknya menjadi berbentuk pedang(gambar 18.6.).
<<<<>>>>
Gambar 18.6. Hasil eksekusi program 18.6.
Huruf-huruf yang digunakan akan kembali normal, bila dilakukan pergantian mode. Cobalah anda buat sebuah program yang akan mengganti mode layar dan lihatlah hasil yang akan terjadi setelah membaca bagian 18.10 dibawah ini.
18.10. MODE LAYAR
Suatu subsistem video bisa memiliki lebih dari satu mode video, tetapi hanya satu mode yang dapat aktif pada satu saat. Banyaknya mode video yang terdapat pada suatu jenis subsistem tergantung pada adapter yang dipakai. Makin canggih adapter yang dipakai, makin banyak pula mode video yang didukungnya. Untuk lebih jelasnya mengenai mode video ini dapat dilihat pada gambar 18.7.
+------+--------+---------+-----------+----------+----------+
| Mode | Teks/ | Jumlah | Resolusi | Sistem | Jumlah |
| | Grafik | Warna/ | | Video | Halaman |
| | | Mono | | | Tampilan |
+------+--------+---------+-----------+----------+----------+
| 00h | T | Gray | 40X 25 | CMEV | 8 |
| 01h | T | 16 | 40X 25 | CMEV | 8 |
| 02h | T | Gray | 80X 25 | CMEV | 8 |
| 03h | T | 16 | 80X 25 | CMEV | 8 |
| 04h | G | 4 | 320X200 | CMEV | 1 |
106
| 05h | G | Gray | 320X200 | CMEV | 1 |
| 06h | G | 2 | 640X200 | CMEV | 1 |
| 07h | T | Mono | 80X 25 | DEV | 8 |
| 0Dh | G | 16 | 320X200 | EV | 8 |
| 0Eh | G | 16 | 640X200 | EV | 4 |
| 0Fh | G | Mono | 640X350 | EV | 2 |
| 10h | G | 16 | 640X350 | EV | 2 |
| 11h | G | Mono | 640X480 | MV | 1 |
| 12h | G | 16 | 640X480 | V | 1 |
| 13h | G | 256 | 320X200 | MV | 1 |
+------+--------+---------+-----------+----------+----------+
Ket. C = CGA (Color Graphics Adapter)
M = MCGA (Memory Controller Card Array)
D = MDA (Monochrome Display Adapter)
E = EGA (Enchanced Graphics Adapter)
V = VGA (Video Graphics Array)
Gambar 18.7. Tabel Mode Video
Setelah melihat tabel mode video, mungkin ada yang heran mengapa setelah mode 07h langsung ke mode 0Dh. Sebenarnya mode- mode di antara kedua mode ini ada, tetapi hanya untuk perangkat video khusus seperti untuk keperluan PCjr yang sudah jarang. Mode video umum dari default DOS adalah mode 03h yaitu teks 80X25.
Dalam inisialisasi mode video ini kita akan menggunakan 2 service dari interupt 10h, yaitu untuk mendapatkan mode video aktif dan merubah mode video.
Untuk mendapatkan mode video aktif gunakan service 0Fh. Setelah pemanggilan service ini, maka beberapa nilai akan dikembalikan ke register yaitu :
- AL = mode video aktif (lihat tabel mode video)
- AH = jumlah karakter per kolom
- BH = halaman tampilan aktif
Halaman tampilan aktif di sini maksudnya adalah nomor dari halaman yang sedang ditampilkan. Jumlah halaman yang terdapat pada suatu sistem video tergantung pada jumlah memori video yang tersedia.
Sedangkan service 00h digunakan untuk merubah mode video. Seperti biasa register AH akan berisi nomor service yang dalam hal ini adalah 00h. Sedangkan mode yang diinginkan diletakkan dalam register AL.
107
SetMode MACRO Mode
MOV AH,00
MOV AL,Mode
INT 10h
ENDM
Setiap kali dilakukan perubahan pada mode video, maka otomatis memori video juga akan dikosongkan dan sebagai akibatnya layar juga akan dibersihkan.
TIP:
Karena setiap kali terjadi pergantian mode layar akan dibersihkan, anda bisa memanfaatkannya untuk membersihkan layar. Misalkan pada modus Teks default(03), dengan mengaktifkan mode 03 juga, maka isi dari layar akan langsung terhapus.
Bila kita tidak menginginkan terjadinya efek pembersihan layar ini, maka nomor mode video pada AL harus dijumlahkan dengan 128 atau dengan kata lain bit ke-7 pada AL dihidupkan. Dengan cara ini maka isi layar yang lama tidak akan hilang setelah perubahan mode.
108
BAB XIX
OPERASI PADA STRING
19.1. INTRUKSI PADA STRING
Apa itu string ? String adalah suatu jenis data yang terdiri atas kumpulan karakter, angka, maupun simbol. Pada operasi string register SI dan DI memegang suatu peranan yang khusus. Register SI(Source Index) digunakan untuk mencatat alamat dari sumber string yang akan dimanipulasi sedangkan register DI(Destination Index) digunakan untuk mencatat alamat atau tempat hasil dari manipulasi string. Operasi pada string secara lengkap bisa anda lihat pada tabel 19.1.
+-------------------------------------------------------------+
| INTRUKSI ARTI |
+-------------------------------------------------------------+
| CLD Clear Direction Flag |
| STD Set Direction Flag |
| |
| CMPS Compare String |
| CMPSB Compare String 1 Byte |
| CMPSW Compare String 1 Word |
| CMPSD Compare String 1 Double Word <80386>|
| |
| LODS Load String |
| LODSB Load String 1 Byte To AL |
| LODSW Load String 1 Word To AX |
| LODSD Load String 1 Double Word To EAX <80386 & |
| 80486> |
| MOVS Move String |
| MOVSB Move String 1 Byte |
| MOVSW Move String 1 Word |
| MOVSD Move String 1 Double Word <80386> |
| |
| REP Repeat |
| REPE Repeat If Equal |
| REPZ Repeat If Zero |
| REPNE Repeat If Not Equal |
| REPNZ Repeat If Not Zero |
109
| |
| SCAS Scan String |
| SCASB Scan String 1 Byte |
| SCASW Scan String 1 Word |
| SCASD Scan String 1 Double Word <80386> |
| |
| STOS Store String |
| STOSB Store AL at ES:DI String |
| STOSW Store AX at ES:DI String |
| STOSD Store EAX at ES:DI String <80386> |
+-------------------------------------------------------------+
Gambar 19.1. Perintah Untuk Operasi String
19.2. PENGCOPYAN DAN ARAH PROSES OPERASI STRING
Sama halnya dengan perintah MOV, pada string digunakan perintah MOVS(Move String) untuk mengcopy data dari DS:SI menuju ES:DI. Pasangan DS:SI mencatat alamat dari sumber string sedangkan ES:DI mencatat alamat hasil dari operasi string.
Setiap kali terjadi operasi string(MOVS) maka register SI dan DI akan berkurang atau bertambah sesuai dengan direction flag. Anda bisa menaikkan nilai SI dan DI pada setiap proses dengan perintah CLD(Clear Direction Flag) dan STD(Set Direction Flag) untuk menurunkan nilai SI dan DI pada setiap proses. Pada saat program dijalankan, secara otomatis direction flag akan menunjuk pada proses menaik.
;/========================================\;
; PROGRAM : STRING1.ASM ;
; AUTHOR : S’to ;
;\========================================/;
.MODEL SMALL
.CODE
ORG 100h
TData : JMP Proses
Kalimat DB 'Donald Duck$' ; 12 karakter
Buffer DB 12 DUP(?)
Proses:
LEA SI,Kalimat ; SI = sumber
LEA DI,Buffer ; DI = tujuan
CLD ; Arah proses menaik
MOV CX,18 ; Banyaknya pengulangan
Ulang :
MOVS ES:Buffer,Kalimat ; Pindahkan data pada
110
LOOP Ulang ; DS:SI ke ES:DI
MOV AH,09 ;
LEA DX,Buffer ;
INT 21h ; Cetak data pada buffer
INT 20h
END TData
Program 19.1. Penggunaan perintah MOVS
Pada program 19.1. dapat anda lihat bagaimana proses pengcopyan data 'Kalimat' ke 'buffer'. Bila program 19.1. dijalankan maka dilayar akan ditampilkan:
Donald Duck
Hasil yang tercetak merupakan data pada buffer yang diambil pada variabel 'kalimat'. Perintah CLD digunakan untuk memastikan supaya arah proses menaik(SI dan DI ditambah setiap kali operasi).
(STD)Menurun <--- DS:SI ---> Menaik(CLD)
_
+---+---+---+---+---+---+---+---+---+---+---+
| D | o | n | a | l | d | | D | u | c | k |
+---+---+---+---+---+---+---+---+---+---+---+
Offset: 103 104 105 106 107 108 109 200 201 202 203
Karena sumber(kalimat) dan tujuan(buffer) pada program 19.1. digunakan tipe data byte(DB) maka oleh assembler perintah MOVS akan dijadikan MOVSB(Move string byte), sehingga register SI dan DI setiap kali proses akan ditambah dengan 1. Bila sumber dan tujuan didefinisikan dengan DW, maka assembler akan menjadikannya MOVSW(Move string word), dan setiap kali operasi SI dan DI akan ditambah dengan 2.
Selain dengan perintah MOVS, anda bisa juga langsung menggunakan perintah MOVSB atau MOVSW. Mungkin ada yang bertanya-tanya, mengapa kita harus menggunakan MOVSB atau MOVSW, jika dengan perintah MOVS assembler akan merubahnya secara otomatis. Bila anda menggunakan perintah MOVSB atau MOVSW secara langsung maka hal ini akan membantu assembler karena ia tidak perlu lagi menterjemahkannya, selain itu program akan lebih efisien.
Intruksi MOVSB dan MOVSW tidak memerlukan operand, oleh karena itu bila pada program 19.1. ingin anda rubah dengan MOVSB, maka pada perintah:
MOVS ES:Buffer,Kalimat
Bisa anda ganti menjadi:
MOVSB
19.3. PENGULANGAN PADA STRING
Pada program 19.1. kita masih menggunakan pengulangan yang primitif. 111
Sebenarnya untuk operasi string ini assembler telah menyediakan beberapa pengulangan khusus, yaitu:
-REP
-REPE
-REPZ
-REPNE
-REPNZ
Perhatikanlah:
Anda hanya bisa menggunakan bentuk pengulangan string bersyarat(REPE,REPZ,REPNE,REPNZ) ini disertai dengan perintah CMPS dan SCAS. Hal ini dikarenakan hanya CMPS dan SCAS yang mempengaruhi zero flag.
Bila pada program 19.1. digunakan perulangan string, maka hasilnya akan menjadi seperti program 19.2.
;/========================================\;
; PROGRAM : STRING2.ASM ;
; AUTHOR : S’to ;
;\========================================/;
.MODEL SMALL
.CODE
ORG 100h
TData : JMP Proses
Kalimat DB 'Donald Duck$' ; 12 karakter
Buffer DB 12 DUP(?)
Proses:
LEA SI,Kalimat ; SI = sumber
LEA DI,Buffer ; DI = tujuan
CLD ; Arah proses menaik
MOV CX,18 ; Banyaknya pengulangan
REP MOVS ES:Buffer,Kalimat ; Pindahkan data
; 'kalimat' ke 'Buffer'
MOV AH,09 ;
LEA DX,Buffer ;
INT 21h ; Cetak Data pada Buffer
INT 20h
END TData
Program 19.2. Penggunaan perintah REP
19.3. PERBANDINGAN PADA STRING
Pada dasarnya perbandingan string sama dengan pengcopyan string. Pada perbandingan string juga terdapat bentuk CMPS yang dapat berupa 112
CMPSB(perbandingan byte), CMPSW(perbandingan word) dan CMPSD(perbandingan double word pada 80386 keatas).
Pada string, perbandingan akan dilakukan pada lokasi memory DS:SI dan ES:DI. Perbandingan bisa dilakukan perByte, PerWord atau perDouble Word(Untuk 80386 keatas).
Cetak_Klm MACRO Kal
MOV AH,09
LEA DX,Kal ; Macro untuk mencetak kalimat
INT 21h
ENDM
;/=======================================\;
; PROGRAM : CMPS.ASM ;
; AUTHOR : S’to ;
; FUNGSI : Menggunakan perbandingan;
; pada string ;
;\=======================================/;
.MODEL SMALL
.CODE
ORG 100h
TData: JMP Proses
Kal1 DB 'akjsdfhakjvhdf'
Kal2 DB 'akjsdfhakPvhdf'
Pesan1 DB 'Kedua kalimat yang dibandingkan sama ! $'
Pesan2 DB 'Kedua kalimat yang dibandingkan tidak sama !$'
Proses :
LEA SI,Kal1
LEA DI,Kal2
CLD ; Arah proses menaik
MOV CX,14 ; Banyaknya perbandingan dilakukan
Ulang :
REP CMPSB ; Bandingkan selama sama
JNE TdkSama ; Jika tidak sama, lompat ke TdkSama
Cetak_Klm Pesan1 ; Cetak pesan tidak sama
JMP EXIT ; Selesai
TdkSama:
Cetak_Klm Pesan2 ; Cetak pesan sama
EXIT :
INT 20h
END TData
Program 19.3. Perbandingan String
Bila program 19.3. dijalankan, maka pada layar akan ditampilkan:
Kedua kalimat yang dibandingkan tidak sama !
Perlu anda perhatikan, bahwa perbandingan akan dilakukan sebanyak 14 kali(Nilai CX) atau terdapat ketidak-samaan pada kedua lokasi memory. Bila ditemukan adanya ketidak samaan, perbandingan akan selesai dilakukan dan register SI dan DI tetap ditambah dengan satu, sehingga akan menunjuk pada karakter selanjutnya(sesudah karakter yang tidak sama, pada contoh 19.3. berupa karakter "v").
19.4. OPERASI SCAN PADA STRING 113
Operasi scan pada string digunakan untuk membandingkan nilai pada register AL, AX atau EAX(80386) dengan data pada ES:DI. Adapun syntax pemakaian SCAN ini adalah:
SCANS Operand
Sama halnya dengan operasi pada string lainnya, bila digunakan perintah diatas, assembler masih akan menerjemahkannya dalam bentuk SCASB(perbandingan AL dengan ES:DI), SCASW(perbandingan AX dengan ES:DI) atau SCASD(perbandingan EAX dengan ES:DI) yang tidak memerlukan operand.
Cetak_Klm MACRO Kal
MOV AH,09 ;
LEA DX,Kal ;
INT 21h ; Macro untuk mencetak kalimat
ENDM
;/==========================================\;
; Program : SCAN.ASM ;
; Author : S’to ;
; Fungsi : Melihat proses pencarian ;
; string (Scan) ;
;\==========================================/;
.MODEL SMALL
.CODE
ORG 100h
TData : JMP Proses
Cari DB 'akddtiuerndfalDfhdadfbn' ; 24 buah karakter
Ketemu DB ' Karakter ''s''yang dicari ketemu ! $'
Tidak DB ' Karakter ''s'' yang dicari tidak ketemu ! $'
Proses:
LEA DI,Cari ; Lokasi dari string yang diScan
MOV AL,'s' ; Karakter yang dicari
MOV CX,24 ; Banyaknya proses Scan
REPNE SCASB ; Scan sebanyak CX atau sampai ZF=1
JNZ Tdk_Ada ; Jika tidak ketemu, maka lompat!
Cetak_Klm Ketemu ; Cetak ketemu
JMP Exit ; Habis
Tdk_Ada:
Cetak_Klm Tidak ; Cetak tidak ketemu
EXIT : INT 20h ; Selesai
END TData
Program 19.4. Operasi Scan pada String
Bila program 19.4. dijalankan, maka pada layar akan ditampilkan:
Karakter 's' yang dicari tidak ketemu !
19.5. MENGAMBIL STRING
LODS merupakan bentuk umum untuk mengambil string dari lokasi memory DS:[SI] menuju AL, AX atau EAX. Sama halnya dengan operasi string lainnya, LODS juga akan diterjemahkan oleh assembler ke dalam bentuk LODSB(DS:[SI] ke 114
AL), LOSW(DS:[SI] ke AX) atau LODSD(DS:[SI] ke EAX<80386>).
19.6. MENGISI STRING
STOS merupakan bentuk umum untuk mengisi string dari AL,AX atau EAX menuju ES:[DI]. Sama halnya dengan operasi string lainnya, STOS juga akan diterjemahkan oleh assembler ke dalam bentuk STOSB(AL ke ES:[DI]), STOSW(AX ke ES:[DI]) atau STOSD(EAX ke ES:[DI] ).
Jika Direction flag bernilai 0(dengan CLD) maka setelah intruksi STOS dijalankan register DI akan ditambah secara otomatis, sebaliknya jika Direction flag bernilai 1(dengan STD) maka register DI akan dikurang secara otomatis. Anda bisa menggunakan intruksi pengulangan pada string disertai dengan perintah STOS ini.
115
BAB XX
MENCETAK ANGKA
20.1. MASALAH DALAM MENCETAK ANGKA
Pada assembler, untuk mencetak suatu angka tidaklah semudah mencetak angka pada bahasa tingkat tinggi. Hal ini dikarenakan baik oleh BIOS maupun DOS tidak disediakan fungsinya. Misalkan kita mempunyai suatu angka 7, untuk mencetaknya kita harus menerjemahkan ke dalam kode ASCII 55 dahulu barulah mencetaknya. Demikian halnya bila ingin mencetak angka 127, maka kita juga harus menterjemahkannya dalam kode ASCII 49, 50 dan 55 untuk kemudian dicetak.
Selanjutnya akan kita lihat, bagaimana caranya untuk mencetak angka dalam bentuk desimal maupun hexadesimal.
20.2. MENCETAK ANGKA DALAM BENTUK DESIMAL
Cara yang paling banyak dilakukan oleh programmer assembler, untuk mencetak angka dalam bentuk desimal adalah dengan membagi angka tersebut dengan 10. Kemudian sisa pembagiannya disimpan dalam stack. Pada saat pencetakan, angka-angka yang disimpan dalam stack akan diambil satu persatu untuk dicetak.
Misalkan anda mempunyai angka 345, maka hasil pembagian dengan 10 sebanyak 3 kali akan menghasilkan sisa berturut-turut 5, 4 dan 3. Sisa pembagian ini kemudian disimpan pada stack. Karena sifat stack yang LIFO
;/============================================\;
; Program : CD-ANGKA.ASM ;
; Author : S’to ;
; Fungsi : Mencetak angka yang bernilai ;
; antara 0 sampai 65535 dalam ;
; format desimal ;
;\============================================/;
.MODEL SMALL
.CODE
ORG 100h
TData :
JMP Proses
Test_Angka DW 65535 ; Angka yang akan dicetak
Proses:
MOV AX,Test_Angka ; AX = angka yang akan dicetak
MOV BX,10 ; BX = penyebut
XOR CX,CX ; CX = 0
Ulang :
XOR DX,DX ; Cegah sisa bagi menjadi pembilang !
DIV BX ; Bagi angka yang akan dicetak dengan 10
PUSH DX ; Simpan sisa bagi dalam stack
116
INC CX ; CX ditambah 1
CMP AX,0 ; Apakah hasil bagi sudah habis ?
JNE Ulang ; Jika belum, ulangi lagi !
Cetak :
POP DX ; Ambil 1 angka yang disimpan
ADD DL,'0' ; Ubah angka tersebut dalam kode ASCII
MOV AH,02 ;
INT 21h ; Cetak angka tersebut
LOOP Cetak ; ulangi
INT 20h
END TData
Program 20.1. Mencetak angka dalam bentuk desimal
Bila program 20.1. dijalankan, maka pada layar akan ditampilkan:
65535
20.3. MENCARI DAN MENAMPILKAN BILANGAN PRIMA
Apa itu bilangan prima? Bilangan prima adalah bilangan yang hanya habis dibagi oleh dirinya sendiri dan 1. Contoh dari bilangan prima ini adalah 2, 3, 5, dan sebagainya.
Secara matematika, untuk mengetest apakah suatu bilangan adalah prima atau bukan, adalah dengan cara pembagian. Misalkan kita ingin mengetahui apakah angka 7 adalah prima atau bukan, kita akan mencoba untuk membaginya dengan 6, 5, 4,..2. Ternyata semua sisa pembagiannya adalah tidak nol atau tidak habis dibagi. Sebagai kesimpulannya, angka 7 adalah prima.
Pada program 20.2. akan anda lihat bagaimana mencari dan menapilkan semua angka prima yang terletak antara angka 0 sampai 1000. Kita akan menggunakan program 20.1. untuk menampilkan angka prima yang telah berhasil dicari.
Cetak_Klm MACRO Klm ; Macro untuk mencetak kalimat
MOV AH,09
LEA DX,Klm
INT 21h
ENDM
CDesimal MACRO Angka
LOCAL Ulang, Cetak
MOV AX,Angka ; AX = angka yang akan dicetak
MOV BX,10 ; BX = penyebut
XOR CX,CX ; CX = 0
Ulang :
XOR DX,DX ; Cegah sisa bagi menjadi pembilang !
DIV BX ; Bagi angka yang akan dicetak dengan 10
PUSH DX ; Simpan sisa bagi dalam stack
INC CX ; CX ditambah 1
CMP AX,0 ; Apakah hasil bagi sudah habis ?
JNE Ulang ; Jika belum, ulangi lagi !
Cetak :
POP DX ; Ambil 1 angka yang disimpan
117PROGRAM BERPARAMETER
22.1. APA ITU PARAMETER ?
Program format, copy dan delete dari Dos tentunya sudah tidak asing lagi bagi kita. Misalkan pada program copy, untuk mengcopy suatu file yang bernama SS.ASM pada drive B: menuju drive C: dengan nama TT.ASM dapat kita tuliskan dengan:
Parameter 1 Parameter 2
+---+----++---+----+
COPY B:SS.ASM C:TT.ASM
Yang dimaksud dengan parameter program adalah semua tulisan yang terdapat dibelakang kata copy(B:SS.ASM dan C:TT.ASM). B:SS.ASM dikatakan sebagai parameter pertama sedangkan C:TT.ASM dikatakan sebagai parameter kedua.
22.2. FILE CONTROL BLOCK
Masih ingatkah anda, pada setiap program COM kita selalu menyediakan 100h byte kosong dengan perintah ORG 100h. 100h byte kosong kosong ini dinamakan sebagai PSP atau Program Segment Prefix dan digunakan oleh DOS untuk mengontrol jalannya program kita. Salah satu pengontrolan yang dilakukan, ialah terhadap paramater program.
PSP sebenarnya masih dibagi-bagi lagi menjadi bagian-bagian yang tugasnya berbeda-beda. Salah satu bagian yang mengatur terhadap parameter program adalah yang dinamakan sebagai FCB(File Control Block). FCB ini terdiri atas 2 bagian, yaitu FCB1 dan FCB2.
FCB1 bertugas menampung parameter pertama dari program, dan berada pada offset 5Ch sampai 6Bh(16 Byte). Sedangkan FCB2 bertugas menampung parameter kedua dari program, dan berada pada offset 6Ch sampai 7Bh(16 Byte).
Ingatlah, bila anda menjalankan sebuah program pada prompt Dos maka yang terakhir dimasukkan pastilah karakter Enter(0Dh).
Cetak_Klm MACRO Klm ; Macro untuk mencetak kalimat
LEA DX,Klm
MOV AH,09
INT 21h
ENDM
Cetak_Kar MACRO Kar ; Macro untuk mencetak karakter
MOV DL,Kar
MOV AH,02
INT 21h
126
ENDM
;/======================================================\;
; Program : FCB12.ASM ;
; Author : S’to ;
; Fungsi : Mencetak isi FCB1 dan FCB2 yang ;
; menampung parameter program. Untuk ;
; mencobanya, tambahkanlah parameter ;
; pada program saat menjalankannya, ;
; seperti: ;
; C:\> FCB12 P111 P222 ;
;\======================================================/;
.MODEL SMALL
.CODE
ORG 100h
TData : JMP Proses
Para1 DB ' Parameter pertama : $'
Para2 DB 13,10,' Parameter kedua : $'
Proses : Cetak_Klm Para1 ; Cetak kalimat Para1
MOV BX,5Ch ; Alamat FCB1
MOV CX,16
Ulang1 :
Cetak_Kar [BX] ; Cetak parameter pertama (FCB1)
INC BX
LOOP Ulang1
Cetak_Klm Para2 ; Cetak kalimat Para2
MOV CX,16
Ulang2 :
Cetak_Kar [BX] ; Cetak parameter kedua (FCB2)
INC BX
LOOP Ulang2
INT 20h
END TData
Program 22.1. Mengambil parameter 1 dan 2 program dari FCB
Untuk mencoba dengan program 22.1., masukkanlah parameter program. Hasil eksekusinya akan tampak seperti:
C:\> FCB12 F111 F222
Parameter pertama : F111
Parameter kedua : F222
22.3. DATA TRANSFER AREA
Dengan FCB kita hanya mampu mengambil 2 parameter dari program. Bagaimana jika parameter yang dimasukkan lebih dari 2?. Untuk itu anda harus mengakses bagian lain dari PSP yang dinamakan sebagai DTA atau Data Tranfer Area. DTA mencatat semua parameter yang dimasukkan pada program.
DTA terletak mulai pada offset ke 80h sampai FFh dari PSP. Bila anda 127
memasukkan parameter dalam program, seperti:
C:\> FCB 111
Maka pada DTA, offset ke 80h akan berisi banyaknya karakter yang diketikkan termasuk karakter enter(Dalam contoh=04). Pada offset ke 81h akan berisi spasi(20h), dan pada offset ke 82h berisi karakter pertama parameter program.
Cetak_Klm MACRO Klm ; Macro untuk mencetak kalimat
LEA DX,Klm
MOV AH,09
INT 21h
ENDM
Cetak_Kar MACRO Kar ; Macro untuk mencetak karakter
MOV DL,Kar
MOV AH,02
INT 21h
ENDM
;/======================================================\;
; Program : DTA.ASM ;
; Author : S’to ;
; Fungsi : Mencetak isi dari DTA program yang ;
; menampung parameter program. Untuk ;
; mencobanya, tambahkanlah parameter ;
; pada program saat menjalankannya, ;
; seperti: ;
; C:\> DTA P111 P222 P333 ;
;\======================================================/;
.MODEL SMALL
.CODE
ORG 100h
TData : JMP Proses
Para DB 13,10,' Parameter program : $'
T_Enter EQU 0Dh
Spasi EQU 20h
Proses : Cetak_Klm Para ; Cetak kalimat Para1
MOV BX,81h ; Alamat DTA
Ulang :
INC BX ; BX = Alamat DTA
CMP BYTE PTR [BX],T_Enter ; Apakah tombol Enter ?
JE Exit ; Ya! Lompat ke Exit
Cetak_Kar [BX] ; Bukan! Cetak karakter tsb
CMP BYTE PTR [BX],Spasi ; Apakah spasi ?
JNE Ulang ; Bukan, lompat ke ulang
Cetak_Klm Para ; Ya! Cetak kalimat
JMP Ulang ; Lompat ke ulang
Exit :
INT 20h
END TData
Program 22.2. Mengambil parameter program dari DTA
Bila program 22.2. dijalankan seperti:
128
C:\>DTA P111 P222 P333
Parameter program : P111
Parameter program : P222
Parameter program : P333
129
BAB XXIII
OPERASI PADA FILE
23.1. PENANGANAN FILE
Pada Dos versi 1.0 penanganan file dilakukan melalui FCB. System ini muncul, sebagai hasil dari kompabilitas dengan CP/M. Ternyata penanganan file melalui FCB ini banyak kendalanya, seperti kemampuan manampung nama file yang hanya 11 karakter. Karena hanya mampu menampung 11 karakter maka nama untuk directory tidak akan tertampung sehingga Dos versi awal tidak bisa menangani adanya directory. Penanganan file melalui FCB ini sudah ketinggalan zaman dan telah banyak ditinggalkan oleh programmer-programmer. Karena itu maka pada buku ini, kita hanya akan membahasnya sekilas.
Pada Dos versi 2.0 diperkenalkan suatu bentuk penanganan file yang baru. Penanganan file ini dinamakan File Handle yang mirip dengan fungsi pada UNIX. Dengan file handle penanganan terhadap directory dengan mudah dilakukan. Operasi file yang dilakukan dengan file handle harus dibuku(Open) terlebih dahulu, selain itu file handle bekerja dengan apa yang dinamakan dengan ASCIIZ. ASCIIZ atau ASCII+Zero byte adalah suatu teknik penulisan string yang diakhiri dengan byte nol(0) atau karakter Null. Contohnya dalam penulisan nama file:
Nama DB 'DATA.DAT ',0 <----- ASCIIZ
23.2. MEMBUAT FILE BARU
Untuk menciptakan suatu file baru, dapat digunakan fungsi 3Ch dari intrupsi 21h. Adapun aturan dari pemakaian interupsi ini adalah dengan memasukkan nilai servis 3Ch pada AH, pasangan register DS:DX menunjuk pada nama file ASCIIZ yang akan diciptakan, CX diisi dengan atribut file atau maksud dari pembukaan file tersebut dengan spesifikasi nomor Bit:
- 0 untuk File Read Only, yaitu file yang dibuka hanya untuk dibaca.
- 1 untuk File Hidden, yaitu file yang disembunyikan. Jenis file ini tidak
akan ditampilkan pada proses DIR dari DOS.
- 2 untuk File System, yaitu file yang akan otomatis dijalankan pada saat
BOOT. Jenis file ini biasanya berkaitan erat dengan mesin komputer dan biasanya ditandai dengan ektensi SYS.
- 3 untuk Volume label.
- 4 untuk Nama subdirectory.
- 5 untuk File Archive, yaitu suatu bentuk file normal.
130
Jika fungsi ini berhasil menciptakan suatu file baru, maka Carry flag akan dijadikan 0(Clear) dan AX akan berisi nomor handle(Nomor pembukaan file). Setiap file yang dibuka akan mempunyai nomor handle yang berbeda-beda, umumnya bernilai 5 keatas. Sebaliknya jika proses penciptaan file gagal, maka Carry flag akan dijadikan 1(Set) dan AX akan berisi kode kesalahan. Adapun kode kesalahan yang sering terjadi adalah:
- 03h artinya Path tidak ditemukan
- 04h artinya Tidak ada handle
- 05h artinya akses terhadap file ditolak
Dalam menggunakan fungsi ini anda harus berhati-hati. Bila pada proses penciptaan file baru dan ternyata file tersebut telah ada, maka fungsi ini akan menjadikan file tersebut menjadi nol. Untuk menghindari hal ini anda bisa menggunakan fungsi 4Eh untuk mengecek apakah file yang akan diciptakan telah ada atau belum.
Create MACRO NamaFile, Attribut, Handle
PUSH CX
PUSH DX
MOV AH,3Ch
MOV CX,Attribut
LEA DX,NamaFile
INT 21h
MOV Handle,AX
POP DX
POP CX
ENDM
23.3. MEMBUKA FILE YANG TELAH ADA
Untuk membuka suatu file yang telah ada, digunakan fungsi 3Dh dari interupsi 21h. Adapun aturan dari pemakaiannya adalah:
INPUT:
AH = 3Dh
AL = Tujuan pembukaan file:
- 00 hanya untuk dibaca (Read Only)
- 01 hanya untuk ditulisi (Write Only)
- 02 untuk ditulis dan dibaca (Read/Write)
DS:DX = Nama file dengan ASCIIZ
131
OUTPUT:
Jika berhasil, maka CF = 0 dan AX = Nomor handle
Jika tidak berhasil, maka CF = 1 dan AX = kode kesalahan
Hati-hatilah:
Pembukaan file yang dilakukan oeh fungsi ini akan memindahkan pointer file pada awal file. Bila anda membuka suatu file dengan fungsi ini dan langsung menulis pada file tersebut, maka isi dari file tersebut akan tertimpa. Untuk menghindari ini pointer file harus dipindahkan pada akhir file sesudah pembukaan. Adapun contoh dari macro untuk membuka file dengan fungsi 3Dh ini adalah:
Open MACRO NamaFile,Attribut,Handle
PUSH DX
MOV AH,3Dh
MOV AL,Attribut
LEA DX,NamaFile
INT 21h
MOV Handle,AX
POP DX
ENDM
23.4. MENUTUP FILE
Untuk menutup suatu file yang telah dibuka, dapat digunakan fungsi ke 3Eh dari interupsi 21h. Fungsi ini akan menutup file yang dibuka dengan 3Dh. Untuk menggunakannya isilah AH dengan 3Eh dan BX dengan nomor handle file tersebut. Adapun contoh dari macro untuk menutup suatu file yang terbuka adalah:
Close MACRO Handle
PUSH BX
MOV AH,3Eh
MOV BX,Handle
INT 21h
POP BX
ENDM
Sebenarnya tidak semua file yang telah dibuka harus ditutup dengan interupsi khusus. Bila anda mengakhiri program tidak dengan interupsi 20h tetapi dengan fungsi 4Ch dari interupsi 21h, maka penutupan file yang terbuka
132
sebenarnya tidak perlu. Hal ini dikarenakan interupsi ini akan menutup semua file yang terbuka secara otomatis. Mengenai fungsi 4Ch dari interupsi 21h ini akan kita bahas lebih lanjut nantinya.
Ingatlah:_
Kemampuan Dos dalam menangani file yang terbuka adalah terbatas. Kemampuan Dos dalam menangani file yang terbuka dapat diatur melalui Config.Sys dengan perintah: Files=n.
23.5. MEMBACA FILE
Pembacaan file handle dapat dilakukan melalui fungsi 3Fh dari interupsi 21h. Adapun aturan dari pemakaian fungsi ini adalah:
INPUT:
AH = 3Fh
CX = Banyaknya data(dalam byte) yang ingin dibaca
BX = Nomor File handle
DS:DX = Alamat buffer tempat hasil pembacaan akan disimpan
OUTPUT:
Jika berhasil, maka CF = 0 dan AX = Jumlah byte yang telah
dibaca. Bila AX=0 atau AX < CX artinya akhir file telah
dicapai.
Jika tidak berhasil, maka CF = 1 dan AX = kode kesalahan
Adapun contoh dari penggunaannya dalam macro adalah:
Read MACRO Handle,Number,Buffer
PUSH BX
PUSH CX
PUSH DX
MOV AH,3Fh
MOV BX,Handle
MOV CX,Number
LEA DX,Buffer
INT 21h
POP DX
POP CX
POP BX
ENDM
133
Perhatikanlah:
Fungsi ini akan membaca banyaknya data dari suatu file dari posisi yang tidak tetap, tergantung dari pointer file pada saat itu. Fungsi ini hanya mampu membaca sebesar 1 segment(64 KB) dalam sekali pembacaan. Untuk membaca file yang besar anda bisa membacanya dengan proses looping. pada proses looping, posisi pointer tidak perlu diatur lagi karena setiap kali selesai pembacaan, pointer akan diatur secara otomatis.
23.6. MENULIS PADA FILE
Untuk menulisi file dapat digunakan fungsi 40h dari interupsi 21h. Adapun aturan dari pemakaian fungsi ini adalah:
INPUT:
AH = 40h
BX = Nomor File Handle
CX = Banyaknya data(dalam byte) yang akan dituliskan
DS:DX = Alamat dari data yang akan ditulis ke file
OUTPUT:
Jika berhasil, maka CF = 0 dan AX = Jumlah byte yang berhasil
dituliskan.
Jika tidak berhasil, maka CF = 1 dan AX = kode kesalahan
Adapun contoh macro dari penggunaan fungsi ini adalah:
Write MACRO Handle,Number,Buffer
PUSH BX
PUSH CX
PUSH DX
MOV AH,40h
MOV BX,Handle
MOV CX,Number
LEA DX,Buffer
INT 21h
POP DX
POP CX
POP BX
ENDM
134
Fungsi ini hampir sama dengan fungsi 3Fh. Dengan melihat pada nilai AX setelah operasi penulisan berhasil, maka dapat diketahui:
- Bila AX = CX, artinya operasi penulisan berhasil dengan sukses.
- Bila AX < CX, artinya penulisan hanya berhasil menulis sebagian
dari data yang seharusnya dituliskan.
Cetak MACRO Kal ; Macro untuk mencetak
MOV AH,09 ; kalimat
LEA DX,Kal
INT 21h
ENDM
;/==============================================\;
; Program : FCOPY.ASM ;
; Author : S’to ;
; Fungsi : Mengcopy file ;
;\==============================================/;
.MODEL SMALL
.CODE
ORG 100h
TData : JMP MULAI
Sumber DB 'Nama file sumber : $'
Tujuan DB 13,10,'Nama file tujuan : $'
File1 DB 70,?,70 Dup (0)
File2 DB 70,?,70 Dup (0)
Handle1 DW ?
Handle2 DW ?
Good DB 13,10,'Pengcopyan File telah dilaksanakan ....$'
Err1 DB 13,10,'Salah perintah .....$'
Err2 DB 13,10,'File tidak ditemukan .....$'
Err3 DB 13,10,'Path tidak ditemukan .....$'
Err4 DB 13,10,'File yang dibuka, kebanyakan ...$'
Err6 DB 13,10,'Penggunaan File handle yang salah ..$'
Err15 DB 13,10,'Spesifikasi Drive yang salah ....$'
Err21 DB 13,10,'Drive tidak siap .....$'
Err29 DB 13,10,'Kesalahan penulisan ....$'
Err30 DB 13,10,'Kesalahan pembacaan ....$'
ErrL DB 13,10,'Kesalahan yang lain .....$'
Mulai :
MOV AX,3 ; Ganti mode
INT 10H ; untuk membersihkan layar
TanyaF1 :
Cetak Sumber ; Cetak kalimat "sumber"
MOV AH,0AH ;
LEA DX,File1 ; Tanya nama file yang ingin
INT 21h ; dicopy
LEA BX,File1 ; Jika user tidak mengetikkan
INC BX ; nama file yang ingin dicopy
CMP BYTE PTR [BX],0 ; atau langsung ditekan enter
JE TanyaF1 ; maka tanya lagi
Ulang1 :
INC BX ;
CMP BYTE PTR [BX],0Dh ;
JNE Ulang1 ; Jadikan file "sumber"
MOV BYTE PTR [BX],0 ; menjadi ASCIZZ
TanyaF2 :
Cetak Tujuan ; Cetak kalimat "tujuan"
135
MOV AH,0AH ; Tanya nama file
LEA DX,File2 ; "tujuan" atau nama file
Int 21h ; hasil pengcopyan
LEA BX,File2 ; Jika user tidak mengetikkan
INC BX ; nama file untuk "tujuan"
CMP BYTE PTR [BX],0 ; atau langsung ditekan enter
JE TanyaF2 ; maka tanya lagi
Ulang2 :
INC BX ;
CMP BYTE PTR [BX],0Dh ;
JNE Ulang2 ; Jadikan file Tujuan
MOV BYTE PTR [BX],0 ; menjadi ASCIZZ
MOV AH,3DH ; Servis buka file
MOV AL,0 ; Mode file Read Only
LEA DX,File1 + 2 ; Nama file "sumber"
INT 21h ;
JC Er ; Jika error, lompat
MOV Handle1,AX ; AX=nomor handle file "sumber"
MOV AH,3CH ; Buat file baru
LEA DX,File2 + 2 ; Dengan nama "tujuan"
MOV CX,00100000b ; File Archive / normal
Int 21h ;
JC Er ; Jika error, lompat
MOV Handle2,AX ; AX=nomor handle file "tujuan"
Copy :
MOV AH,3FH ; servis baca file
MOV BX,Handle1 ; Baca file "sumber"
MOV CX,1024 ; Banyaknya pembacaan
LEA DX,Buffer ; Lokasi penampungan
INT 21h ;
JC Er ; Jika error, lompat
CMP AX, 0 ; Pembacaan file sudah EOF?
JE Selesai ; Ya, exit
MOV CX,AX ; Banyaknya data
MOV AH,40h ; Servis tulis file
MOV BX,Handle2 ; Tulis file "Tujuan"
LEA DX,Buffer ; Lokasi data
Int 21h
JC Er ; Jika error, lompat
CMP CX,AX ; File habis dicopy?
JE Copy ; belum, ulangi
Selesai :
Cetak Good ; Pengcopyan selesai
MOV AH,3Fh ; Tutup file
MOV BX,Handle1 ; "sumber"
INT 21h ;
MOV BX,Handle2 ; Tutup file
INT 21h ; "Tujuan"
EXIT :
INT 20h ; Selesai
Er :
CMP AX,1
JNE NotErr1
Cetak Err1
JMP EXIT
NotErr1 :
CMP AX,2
136
JNE NotErr2
Cetak Err2
JMP EXIT
NotErr2 :
CMP AX,3
JNE NotErr3
Cetak Err3
JMP EXIT
NotErr3 :
CMP AX,4
JNE NotErr4
Cetak Err4
JMP EXIT
NotErr4 :
CMP AX,6
JNE NotErr6
Cetak Err6
JMP EXIT
NotErr6 :
CMP AX,21
JNE NotErr21
Cetak Err21
JMP EXIT
NotErr21 :
CMP AX,29
JNE NotErr29
Cetak Err29
JMP EXIT
NotErr29 :
CMP AX,30
JNE NotErr30
Cetak Err30
JMP EXIT
NotErr30 :
Cetak ErrL
JMP EXIT
Buffer LABEL BYTE
END TData
Program 23.1. Mengcopy File
Bila program 23.1. dijalankan, maka program akan meminta anda memasukan nama file yang akan dicopy dan nama file hasil copy-an, seperti:
Nama file sumber : TASM.EXE
Nama file tujuan : B:SS.PROG
Maka file TASM.EXE akan dicopykan pada drive b: dengan nama SS.PROG. Bila pengcopyan file berhasil dengan sukses, maka pada layar akan ditampilkan:
Pengcopyan File telah dilaksanakan ....
Keterangan program:
MOV AX,3
INT 10H
Ini adalah perintah untuk mengaktifkan mode layar 03, atau mode default 137
dari DOS. Dengan pengaktifan mode layar ini seluruh isi layar akan terhapus.
TanyaF1 :
Cetak Sumber
MOV AH,0AH
LEA DX,File1
INT 21h
Mintalah dari user untuk memasukkan nama file yang akan dicopy. Hasil input dari user ini, disimpan pada varibel penampung "File1" yang didefinisikan untuk mampu menampung sampai 70 karakter.
LEA BX,File1
INC BX
CMP BYTE PTR [BX],0
JE TanyaF1
Ulang1 :
INC BX
CMP BYTE PTR [BX],0Dh
JNE Ulang1
MOV BYTE PTR [BX],0
Setelah didapat nama file yang ingin dicopy, jadikanlah nama file tersebut menjadi ASCIZZ. Karena setiap input dari keyboard selalu diakhiri dengan enter(0Dh), maka kita tinggal mencari karakter enter tersebut dan menggantinya dengan byte 0, untuk membuatnya menjadi ASCIZZ.
TanyaF2 :
Cetak Tujuan
MOV AH,0AH
LEA DX,File2
Int 21h
LEA BX,File2
INC BX
CMP BYTE PTR [BX],0
JE TanyaF2
Ulang2 :
138
INC BX
CMP BYTE PTR [BX],0Dh
JNE Ulang2
MOV BYTE PTR [BX],0
Proses untuk menanyakan nama file hasil copy-an, sama dengan proses meminta nama file yang ingin dicopy. Nama file hasil copyan juga dijadikan ASCIIZ.
MOV AH,3DH
MOV AL,0
LEA DX,File1 + 2
INT 21h
JC Er
MOV Handle1,AX
Bukalah file yang akan dicopy dengan atribut pembukaan 0, atau Read Only. Nomor handle file tersebut akan diberikan oleh DOS berupa suatu angka. Simpanlah nomor handle yang diberikan DOS untuk file yang dibuka ini. Untuk selanjutnya anda tinggal menggunakan nomor handle dari file ini untuk mengaksesnya.
MOV AH,3CH
LEA DX,File2 + 2
MOV CX,00100000b
INT 21h
JC Er
MOV Handle2,AX
Buatlah sebuah file baru dengan atribut pembukaan 32 atau file archive(normal). Simpanlah nomor handle yang diberikan DOS untuk file yang baru diciptakan ini. Jika file yang baru diciptakan ini telah ada pada disk sebelumnya, maka file tersebut akan dihapus.
Copy :
MOV AH,3FH
MOV BX,Handle1
MOV CX,1024
LEA DX,Buffer
INT 21h
JC Er
CMP AX, 0
139
JE Selesai
MOV CX,AX
MOV AH,40h
MOV BX,Handle2
LEA DX,Buffer
Int 21h
JC Er
CMP CX,AX
JAE Copy
Setelah itu, bacalah file yang akan dicopy sebanyak 1024 byte, dan disimpan pada variabel penampung buffer. Setelah pembacaan, lakukanlah penulisan kepada file baru sebanyak byte yang berhasil dibaca. Proses baca dan tulis ini dilakukan terus sampai file tersebut berhasil dicopykan semuanya.
Perhatikanlah:
Untuk membaca file yang dicopy dan menulisi file baru, kita tinggal menggunakan nomor handle yang kita dapatkan pada saat pembukaan dan pembuatan file tersebut.
Selesai :
Cetak Good
MOV AH,3Fh
MOV BX,Handle1
INT 21h
MOV BX,Handle2
INT 21h
EXIT :
INT 20h
Setelah proses pengcopyan file selesai, tutuplah file tersebut dengan menggunakan nomor handle-nya.
Er :
CMP AX,1
JNE NotErr1
Cetak Err1
JMP EXIT
140
NotErr1 :
CMP AX,2
JNE NotErr2
Cetak Err2
JMP EXIT
NotErr2 :
CMP AX,3
JNE NotErr3
Cetak Err3
JMP EXIT
NotErr3 :
CMP AX,4
JNE NotErr4
Cetak Err4
JMP EXIT
NotErr4 :
CMP AX,6
JNE NotErr6
Cetak Err6
JMP EXIT
NotErr6 :
CMP AX,21
JNE NotErr21
Cetak Err21
JMP EXIT
NotErr21 :
CMP AX,29
JNE NotErr29
Cetak Err29
JMP EXIT
NotErr29 :
CMP AX,30
JNE NotErr30
Cetak Err30
JMP EXIT
NotErr30 :
Cetak ErrL
141
JMP EXIT
Ini adalah bagian yang akan menerjemahkan kode kesalahan dari Dos. Proses yang dilakukan memang agak sedikit bertele-tele, karena dibandingkan satu persatu. Kita akan mempelajari cara/teknik untuk menerjemahkan kode kesalahan ini secara profesional pada bagian 23.11.
Buffer LABEL BYTE
Ini adalah suatu pendefinisian data istimewa dalam assembler. Dengan mendefinisikannya pada akhir file, akan kita dapatkan suatu buffer/penampung yang besar sekali (sebatas memory yang tersedia). Untuk lebih jelasnya anda bisa lompat pada bagian 24.7. sebentar, untuk membaca keterangan mengenai tipe data ini.
23.7. MENGHAPUS FILE
Untuk menghapus suatu file, dapat digunakan fungsi ke 41h dari interupsi 21h. Adapun aturan dari pemakaian fungsi ini adalah:
INPUT:
AH = 41h
DS:DX = Nama file(ASCIIZ) yang akan dihapus
OUTPUT:
Jika berhasil, maka CF = 0
Jika tidak berhasil, maka CF = 1 dan AX = kode kesalahan
Perlu anda ketahui, fungsi ini tidak mendukung karakter khusus seperti '?' dan '*' dari Dos. Dengan demikian fungsi ini hanya mampu menghapus 1 buah file setiap saat.
Delete MACRO Nama
MOV AH,41h ; Servis untuk menghapus file
LEA DX,Nama ; DS:DX menunjuk pada nama file
INT 21h
ENDM
;/======================================================\;
; Program : HAPUS.ASM ;
; Author : S’to ;
; Fungsi : Menghapus file, seperti perintah;
; delete dari Dos. ;
;\======================================================/;
.MODEL SMALL
.CODE
ORG 100h
TData :JMP Proses
Error DB ' Sorry, File anda tidak bisa dihapus !',13,10
DB ' Anda harus menggunakan parameter ',13,10
DB ' seperti: ',13,10
142
DB ' C:\> Hapus FILE_X ',13,10,10
DB ' untuk menghapus file FILE_X $'
Proses : MOV DI,80h ; Alamat awal parameter
MOV AL,0Dh ; Karakter Enter
REPNE SCASB ; Cari karakter Enter
DEC DI ; DI menunjuk karakter Enter
MOV AL,0 ; Jadikan ASCIIZ
STOSB ; Letakkan byte 0 pada DS:[DI]
MOV DI,82h ; Awal String
Delete [DI] ; Hapus file parameter
JNC Exit ; Jika tidak ada kesalahan, Habis
MOV AH,09 ; Jika ada kesalahan
LEA DX,Error ; Tampilkan peringatan !
INT 21h
Exit :
INT 20h
END TData
Program 23.2. Menghapus File
Program 23.2. bisa anda gunakan untuk menghapus suatu file dengan parameter. Misalkan file COBA.TXT akan dihapus, maka bisa dihapus dengan cara:
HAPUS COBA.TXT
23.8. MEMINDAHKAN PENUNJUK(POINTER) FILE
Pada file terdapat pointer(penunjuk) yang berguna untuk menunjukkan suatu lokasi tertentu pada file. Dengan fungsi 42h dari Dos, penunjuk file ini dapat dipindah-pindahkan. Adapun aturan dari penggunaan fungsi ini adalah:
INPUT:
AH = 42h
BX = Handle
CX = Offset Hi(tinggi) yang menunjukkan besarnya perpindahan
DX = Offset Lo(rendah) yang menunjukkan besarnya perpindahan
AL = Mode perpindahan, dengan nilai:
00 untuk berpindah dari awal file
01 untuk berpindah terhadap posisi sekarang
02 untuk berpindah dari akhir file
OUTPUT:
Jika berhasil, maka CF = 0 dan DX:AX = menunjuk pada posisi baru
Jika tidak berhasil, maka CF = 1 dan AX = kode kesalahan
Adapun contoh macro dari penggunaan fungsi ini adalah:
143
Seek MACRO Handle,Mode,OffsetLo,OffsetHi
PUSH BX
PUSH CX
MOV AH,42h
MOV AL,Mode
MOV BX,Handle
MOV CX,OffsetHi
MOV DX,OffsetLo
INT 21h
POP CX
POP BX
ENDM
23.9. MENGATUR ATRIBUT FILE
Seperti yang telah kita ketahui, pada file terdapat suatu byte yang digunakan sebagai atribut dari file tersebut. Atribut ini menentukan jenis dari file tersebut(lihat sub bab 23.2).
DOS menyediakan fungsi ke 43h untuk mengatur atribut file. Adapun aturan dari pemakaian fungsi ini adalah:
INPUT:
AH = 43h
AL = Mode, dengan spesifikasi
00 untuk melihat atribut dari suatu file
01 untuk mengubah atribut dari suatu file
DS:AX = Nama file dalam bentuk ASCIIZ
CX = Atribut, dengan spesifikasi Nomor bit:
- 0 untuk File Read Only
- 1 untuk File Hidden
- 2 untuk File System
- 3 untuk Volume label.
- 4 untuk Nama subdirectory.
- 5 untuk File Archive
OUTPUT:
Jika berhasil, maka CF = 0 dan CX menunjukkan atribut dari
file, jika mode pada AL=0
Jika tidak berhasil, maka CF = 1 dan AX = kode kesalahan
Cetak_Kal MACRO Kal ; Macro untuk mencetak kalimat
144
MOV AH,09
LEA DX,Kal
INT 21h
ENDM
;/==================================================\;
; Program : ATTR.ASM ;
; Author : S’to ;
; Fungsi : Melihat atribut dari file. ;
; Anda bisa menggunakan parameter;
; dengan program ini ;
;\==================================================/;
.MODEL SMALL
.CODE
ORG 100h
TData : JMP Proses
Error DB 'Sorry, file tidak ditemukan atau ',13,10
DB ' anda tidak mengunakan parameter $'
Jenis DB 'Jenis File ini : $'
Attr1 DB 13,10,'-> Read Only $'
Attr2 DB 13,10,'-> Hidden $'
Attr3 DB 13,10,'-> System $'
Attr4 DB 13,10,'-> Volume $'
Attr5 DB 13,10,'-> Nama Directory $'
Attr6 DB 13,10,'-> Archive $'
Tabel DW Attr1,Attr2,Attr3,Attr4,Attr5,Attr6
Proses:
MOV BX,82h ; Alamat DTA, Awal parameter
Ulang :
CMP BYTE PTR [BX],0Dh ; Apakah=Enter?
JE ASCIIZ ; Ya, Jadikan ASCIIZ
INC BX ; tunjuk karakter selanjutnya
JMP Ulang ; ulangi, cari enter
ASCIIZ:
MOV BYTE PTR[BX],0 ; Jadikan ASCIIZ
MOV AH,43h ; Servis untuk atribut file
MOV DX,82h ; DX = Awal nama file ASCIIZ
MOV AL,00 ; Untuk membaca atribut
INT 21h ; Baca atribut file
JNC Good ; Jika tidak error lompat
Cetak_Kal Error ; Error, cetak pesan dan
JMP Exit ; Selesai
Good :
Cetak_Kal Jenis ; Cetak kalimat
MOV AX,1 ; AX untuk mengetes Bit
XOR BX,BX ; BX=penunjuk isi Tabel
CEK :
PUSH AX ;
PUSH BX ; simpan isi register
PUSH CX ;
AND CX,AX ; Mengetest bit
JCXZ Tidak ; Jika CX=0 artinya bit=0
ADD BX,BX ; BX kali 2, untuk akses Tabel
MOV AH,09 ; Servis cetak kalimat
MOV DX,Tabel[BX] ; Alamat offset dari kalimat
INT 21h ; Cetak kalimat
Tidak :
POP CX ;
POP BX ; Ambil nilai register
POP AX ;
ADD AX,AX ; AX untuk test bit berikutnya
145
INC BX ; BX=Banyaknya pengulangan
CMP BX,6 ; Apakah telah mengetest 6 bit?
JE Exit ; Ya! selesai
JMP CEK ; Ulangi, test bit berikutnya
Exit :
INT 20h
END TData
Program 23.3. Melihat Atribut File
Dengan program 23.3. anda bisa melihat atribut dari suatu file, termasuk file hidden, seperti IO.SYS. Untuk melihat atribut dari file tersebut ketikkan:
C:\>ATTR IO.SYS
Jenis File ini :
-> Read Only
-> Hidden
-> System
-> Archive
Mengenai penggunaan Tabel, akan dijelaskan pada sub bab 23.11 yang menjelaskan mengenai teknik untuk menerjemahkan kode kesalahan Dos dengan cepat dan mudah.
23.10. MENGUBAH NAMA FILE
Untuk mengganti nama suatu file, dapat digunakan fungsi ke 56h dari Dos. Adapun aturan dari pemakaian fungsi ini adalah:
INPUT:
AH = 56h
DS:DX = Nama file lama (ASCIIZ)
ES:DI = Nama file baru (ASCIIZ)
OUTPUT:
Jika berhasil, maka CF = 0
Jika tidak berhasil, maka CF = 1 dan AX = kode kesalahan
23.11. KODE KESALAHAN DOS
Pada bab ini, kita telah banyak menyinggung mengenai kode kesalahan. Kode kesalahan umumnya dilaporkan dalam register AX setelah suatu operasi mengalami kesalahan(Error). Adapun arti dari kode kesalahan ini, bisa anda lihat pada gambar 23.1.
146
-------------------------------------------------------------
Kode salah Arti Kode Salah
-------------------------------------------------------------
01 Salah perintah
02 File tidak ditemukan
03 Path tidak ditemukan
04 File yang dibuka terlalu banyak
05 Operasi ditolak
06 penggunaan file handle yang salah
07 MCB(Memory Control Blocks) telah rusak
08 Kekurangan memory
09 Kesalahan alamat memory blok
10 Kesalahan environment string
11 Kesalahan format
12 Kesalahan kode akses
13 Kesalahan data
15 Kesalahan spesifikasi drive
16 Tidak dapat menghapus directory aktif
17 Device yang tidak sama
18 Tidak ada file yang ditemukan lagi
19 Tidak dapat menulis pada disket yang diprotek
20 Unit tidak diketahui
21 Drive belum siap
22 Perintah tidak diketahui
23 Data disk terdapat kesalahan
25 Pencarian alamat pada disket ada kesalahan
26 Tipe media tidak diketahui
27 Pencarian nomor sektor tidak ditemukan
28 Printer tidak diberi kertas
29 Kesalahan pada saat penulisan
30 Kesalahan pada saat pembacaan
61 Queue Printer telah penuh
65 Perintah ditolak
80 File telah ada
82 Tidak bisa membuat entri directory
83 Kesalahan pada interupsi 24
86 Kesalahan password
147
87 Kesalahan parameter
-------------------------------------------------------------
Gambar 23.1. Arti dari kode kesalahan DOS yang umum
Pada program yang lengkap biasanya bila terdapat error, akan dilaporkan kepada pemakainya. Cara yang kuno untuk digunakan untuk mencetak arti kesalahan adalah dengan membandingkan kode kesalahan yang dihasilkan dan mencetak pesannya, seperti:
TData: JMP Proses
Error1 DB ' Salah perintah ! $'
Error2 DB ' File tidak ditemukan ! $'
Error3 DB ' Path tidak ditemukan ! $'
:
Proses: :
CMP AX,1 ; Apakah error kode 1 ?
JNE Err2 ; Bukan! lompat ke Err2
Cetak Error1 ; Ya! Cetak pesan dari kode error 1
JMP Exit ; Keluar
Err2:
CMP AX,2 ; Apakah error kode 2 ?
JNE Err3 ; Bukan! lompat ke Err3
Cetak Error2 ; Ya! Cetak pesan dari kode error 2
JMP Exit ; Keluar
Err3:
CMP AX,3 ; Apakah error kode 3 ?
JNE Err4 ; Bukan! lompat ke Err4
Cetak Error3 ; Ya! Cetak pesan dari kode error 3
JMP Exit ; Keluar
Err4:
:
:
Apakah cara diatas sudah tepat ? Tidak!. Bila pengecekan dari kode kesalahan hanyalah 1 atau 2 buah, cara diatas dapat anda gunakan. Bagaimana jika kode kesalahan yang akan kita cek, ternyata jumlahnya mencapai ratusan?
148
Program anda akan tampak bertele-tele dan panjang selain itu ukuran file akan menjadi sangat besar.
Salah satu cara yang dapat anda gunakan untuk memecahkan masalah diatas adalah dengan membuat suatu tabel array yang berisi alamat offset dari masing-masing pesan kesalahan. Kemudian dari tabel alamat kode kesalahan ini digunakan untuk mencetak pesan salah yang dihasilkan.
Cetak MACRO Kal
MOV AH,09
MOV DX,Kal
INT 21h
ENDM
;/================================================\;
; Program : ERROR.ASM ;
; Author : S’to ;
; Fungsi : Mencetak pesan kode error ;
; dengan cara yang praktis. ;
;\================================================/;
.MODEL SMALL
.CODE
ORG 100h
TData : JMP Proses
Error01 DB 'Salah perintah $'
Error02 DB 'File tidak ditemukan $'
Error03 DB 'Path tidak ditemukan $'
Error04 DB 'File yang dibuka terlalu banyak $'
Error05 DB 'Operasi ditolak $'
Error06 DB 'Penggunaan file handle yang salah $'
Error07 DB 'MCB(Memory Control Blocks) telah rusak $'
Error08 DB 'Kekurangan memory $'
Error09 DB 'Alamat memory blok salah $'
Error10 DB 'Environment String salah $'
Error11 DB 'Kesalahan format $'
Error12 DB 'Kode akses salah $'
Tabel DW Error01,Error02,Error03,Error04,Error05
DW Error06,Error07,Error08,Error09,Error10
DW Error11,Error12
Test_Error DW 03
Proses :
MOV AX,Test_Error
DEC AX
ADD AX,AX
MOV BX,AX
CETAK Tabel[BX] ; Cetak pesan kode error
INT 20h
END TData
Program 23.4. Cara yang praktis untuk mencetak arti kode kesalahan DOS
Bila program 23.4. dijalankan, maka pada layar akan tercetak:
Path tidak ditemukan 149
Seperti yang diharapkan, arti kode error 03(Test_Error) akan tercetak pada layar. Anda bisa mengubah kode salah pada variabel Test_Error dengan angka 01 sampai 12 untuk melihat pesan yang akan ditampilkan.
Perhatikanlah:
Pada varibel Tabel kita mencatat alamat offet dari masing- masing pesan kesalahan dengan cara:
Tabel DW Error01,Error02,Error03,Error04,Error05
DW Error06,Error07,Error08,Error09,Error10
DW Error11,Error12
dimana masing-masing alamat offset menggunakan 1 word.
MOV AX,Test_Error
DEC AX
Karena kode error yang pertama adalah 01, maka perlu kita kurangi dengan 1 supaya menjadi 0. Dengan demikian kode error 1 akan menunjuk pada word pertama pada Tabel yang kita ketahui bahwa word pertama dari Tabel merupakan alamat offset pesan kode salah 01.
ADD AX,AX
MOV BX,AX
Karena setiap alamat offset dari pesan kode salah menggunakan 1 word atau 2 byte, maka untuk mengambil word selanjutnya dari Tabel yang mencatat alamat offset pesan kode error selanjutnya, kita harus mengalikan kode error dengan 2 atau menambah kode error dengan dirinya sendiri.
CETAK Tabel[BX]
Kemudian dengan Register Indirect Addressing kita mengambil alamat offset pesan kode salah dari Tabel. Seperti biasa, pada pencetakan kalimat kita mengambil alamat offset dari suatu string yang diakhiri dengan tanda '$' untuk dicetak dengan fungsi 09 dari Dos. Pada pencetakan string ini alamat offset sudah didapat dari Tabel[BX], sehingga perintah: "LEA DX,Kal" dari fungsi 09 dapat dirubah menjadi: "MOV DX,Kal"
150
Subscribe to:
Postingan (Atom)